1602液晶显示模块的应用

液晶显示器以其微功耗、体积小、显示内容丰富、超薄轻巧的诸多优点，在各类仪表和低功耗系统中得到广泛的应用。

根据显示内容可以分为字符型液晶，图形液晶。根据显示容量又可以分为单行16字，2行16字，两行20字等等。

这里介绍常用的字16字X2行的字符型液晶模块的使用方法。这是一种通用模块。与数码管相比该模块有如下优点：

1.位数多，可显示32位，32个数码管体积相当庞大了

2.显示内容丰富，可显示所有数字和大、小写字母

3.程序简单，如果用数码管动态显示，会占用很多时间来刷新显示，而1602自动完成此功能。

1602采用标准的16脚接口，其中：（模块背面有标注）

第1脚：VSS为地电源

第2脚：VDD接5V正电源

第3脚：V0为液晶显示器对比度调整端，接正电源时对比度最弱，接地电源时对比度最高，对比度过高时会产生“鬼影”，使用时可以通过一个10K的电位器调整对比度（建议接地，弄不好有的模块会不显示）

第4脚：RS为寄存器选择，高电平时选择数据寄存器、低电平时选择指令寄存器。

第5脚：RW为读写信号线，高电平时进行读操作，低电平时进行写操作。

第6脚：E端为使能端，当E端由高电平跳变成低电平时，液晶模块执行命令。

第7～14脚：D0～D7为8位双向数据线。

第15～16脚：空脚（有的用来接背光）

1602液晶模块内部的字符发生存储器（CGROM)已经存储了不同的点阵字符图形，这些字符有，阿拉伯数字、英文字母的大小写、常用的符号、和日文假名等，每一个字符都有一个固定的代码，其中数字与字母同ASCII码兼容。

其内部还有自定义字符（CGRAM），可用业存储自已定义的字符。

1602模块的设定，读写，与光标控制都是通过指令来完成，共有11条指令，如下：

指令1：清显示，光标复位到地址00H位置。

指令2：光标复位，光标返回到地址00H。

指令3：光标和显示模式设置 I/D：光标移动方向，高电平右移，低电平左移，S:屏幕上所有文字是否左移或者右移。高电平表示有效，低电平则无效。

指令4：显示开关控制。 D：控制整体显示的开与关，高电平表示开显示，低电平表示关显示 C：控制光标的开与关，高电平表示有光标，低电平表示无光标 B：控制光标是否闪烁，高电平闪烁，低电平不闪烁。

指令5：光标或显示移位 S/C：高电平时移动显示的文字，低电平时移动光标。R/L，高向左，低向右。

指令6：功能设置命令 DL：高电平时为4位总线，低电平时为8位总线 N：低电平时为单行显示，高电平时双行显示 F: 低电平时显示5x7的点阵字符，高电平时显示5x10的点阵字符。（有些模块是 DL：高电平时为8位总线，低电平时为4位总线）

指令7：字符发生器RAM地址设置，地址：字符地址*8+字符行数。(将一个字符分成5*8点阵，一次写入一行，8行就组成一个字符)

指令8：置显示地址，第一行为：00H——0FH,第二行为：40H——4FH。

指令9：读忙信号和光标地址 BF：为忙标志位，高电平表示忙，此时模块不能接收命令或者数据，如果为低电平表示不忙。

指令10：写数据。

指令11：读数据。

以下是在液晶模块的第二行第一个字符的位置显示字母“A”的程序：

[Keil uVision2编译通过，AT89S51+12M晶振+JHD 162A模块成功显示]

        ORG 0000H
        RS EQU P3.7   ;确定具体硬件的连接方式
        RW EQU P3.6   ;确定具体硬件的连接方式
        E EQU P3.5    ;确定具体硬件的连接方式
        MOV P1,#00000001B     ;清屏并光标复位
        ACALL ENABLE  ;调用写入命令子程序
        MOV P1,#00111000B     ;设置显示模式,8位2行5X7点阵
        ACALL ENABLE  ;调用写入命令子程序
        MOV P1,#00001111B     ;显示器开、光标开、光标允许闪烁
        ACALL ENABLE  ;调用写入命令子程序
        MOV P1,#00000110B     ;文字不动，光标自动右移
        ACALL ENABLE  ;调用写入命令子程序
        MOV P1,#0C0H  ;写入显示起始地址（第二行第一个位置）
        ACALL ENABLE  ;调用写入命令子程序
        MOV P1,#01000001B     ;字母A的代码
        SETB RS       ;RS=1
        CLR RW        ;RW=0 ;准备写入数据
        CLR E         ;E=0 ;执行显示命令
        ACALL DELAY   ;判断液晶模块是否忙?
        SETB E        ;E=1 ;显示完成,程序停车
        AJMP $
ENABLE: 
        CLR RS        ;写入控制命令的子程序
        CLR RW
        CLR E
        ACALL DELAY
        SETB E
        RET
DELAY:  
        MOV P1,#0FFH  ;判断液晶显示器是否忙的子程序
        CLR RS
        SETB RW
        CLR E
        NOP
        SETB E
        JB P1.7,DELAY ;如果P1.7为高电平表示忙就循环等待
        RET
        END