JZ2440裸板之SDRAM启动分析

启动文件head.S源码：

@*************************************************************************

@ File：head.S

@ 功能：设置SDRAM，将程序复制到SDRAM，然后跳到SDRAM继续执行

@*************************************************************************       

.equ        MEM_CTL_BASE,       0x48000000

.equ        SDRAM_BASE,         0x30000000

.text

.global _start

_start:

    bl  disable_watch_dog               @ 关闭WATCHDOG，否则CPU会不断重启

    bl  memsetup                             @ 设置存储控制器

    bl  copy_steppingstone_to_sdram     @ 复制代码到SDRAM中

    ldr pc, =on_sdram                      @ 跳到SDRAM中继续执行

on_sdram:

    ldr sp, =0x34000000                   @ 设置堆栈

    bl  main

halt_loop:

    b   halt_loop

disable_watch_dog:

    @ 往WATCHDOG寄存器写0即可

    mov r1,     #0x53000000

    mov r2,     #0x0

    str r2,     [r1]

    mov pc,     lr      @ 返回

copy_steppingstone_to_sdram:

    @ 将Steppingstone的4K数据全部复制到SDRAM中去

    @ Steppingstone起始地址为0x00000000，SDRAM中起始地址为0x30000000

    mov r1, #0

    ldr r2, =SDRAM_BASE

    mov r3, #4*1024

1:  

    ldr r4, [r1],#4     @ 从Steppingstone读取4字节的数据，并让源地址加4

    str r4, [r2],#4      @ 将此4字节的数据复制到SDRAM中，并让目地地址加4

    cmp r1, r3          @ 判断是否完成：源地址等于Steppingstone的未地址？

    bne 1b               @ 若没有复制完，继续

    mov pc,     lr      @ 返回

memsetup:

    @ 设置存储控制器以便使用SDRAM等外设

    mov r1,     #MEM_CTL_BASE       @ 存储控制器的13个寄存器的开始地址

    adrl    r2, mem_cfg_val                @ 这13个值的起始存储地址

    add r3,     r1, #52                         @ 13*4 = 54

1:  

    ldr r4,     [r2], #4            @ 读取设置值，并让r2加4

    str r4,     [r1], #4            @ 将此值写入寄存器，并让r1加4

    cmp r1,     r3                  @ 判断是否设置完所有13个寄存器

    bne 1b                          @ 若没有写成，继续

    mov pc,     lr                  @ 返回

.align 4

mem_cfg_val:

    @ 存储控制器13个寄存器的设置值

    .long   0x22011110      @ BWSCON

    .long   0x00000700      @ BANKCON0

    .long   0x00000700      @ BANKCON1

    .long   0x00000700      @ BANKCON2

    .long   0x00000700      @ BANKCON3  

    .long   0x00000700      @ BANKCON4

    .long   0x00000700      @ BANKCON5

    .long   0x00018005      @ BANKCON6

    .long   0x00018005      @ BANKCON7

    .long   0x008C07A3      @ REFRESH

    .long   0x000000B1      @ BANKSIZE

    .long   0x00000030      @ MRSRB6

    .long   0x00000030      @ MRSRB7

====================================================================

leds.c源码：

#define    GPFCON        (*(volatile unsigned long *)0x56000050)

#define    GPFDAT        (*(volatile unsigned long *)0x56000054)

#define    GPF4_out    (1<<(4*2))

#define    GPF5_out    (1<<(5*2))

#define    GPF6_out    (1<<(6*2))

void  wait(volatile unsigned long dly)

{

    for(; dly > 0; dly--);

}

int main(void)

{

    unsigned long i = 0;

    GPFCON = GPF4_out|GPF5_out|GPF6_out;    // 将LED1,2,4对应的GPF4/5/6三个引脚设为输出

    while(1){

        wait(30000);

        GPFDAT = (~(i<<4));                 // 根据i的值，点亮LED1,2,4

        if(++i == 8)

            i = 0;

    }

    return 0;

}

====================================================================

Makefile文件：

sdram.bin : head.S  leds.c

    arm-linux-gcc  -c -o head.o head.S

    arm-linux-gcc -c -o leds.o leds.c

    arm-linux-ld -Ttext 0x30000000 head.o leds.o -o sdram_elf

    arm-linux-objcopy -O binary -S sdram_elf sdram.bin

    arm-linux-objdump -D -m arm  sdram_elf > sdram.dis

clean:

    rm -f   sdram.dis sdram.bin sdram_elf *.o

====================================================================

注意：

       虽然nor flash、网卡和SDRAM的接口一样都是内存类接口，但是SDRAM属于内存类设备，nor flash、网卡不属于内存类设备，叫做RAM Like。

       此实验在测试时不能直接下载到内存中直接运行，要先烧写到nand flash中再运行，否则从片内内存拷贝4k到SDRAM中运行系统会崩溃。

       具体下载方法参见：“JZ2440开发板裸板烧写方法”