S3C6410，Tiny6410，Mini6410，MoblieDDR内存驱动-电子工程世界

分享到: 微博; QQ; 微信; LinkedIn

1. 概述

S3C6410内存控制器是采用的PL340内存控制芯片。AMBA APB3.0接口协议规定，可以通过编程将AXI从总线接口和APB主总线接口进行桥接，实现二者总线上的数据的传输。

DRAM控制器可以通过配置兼容SDRAM类型芯片。通过向DRAM控制器中PL340写入内存芯片配置参数，内存时序，来控制内存工作。

DRAM控制器可以直接从SDRAM或DRAM接收一个控制命令。通过将操作命令写入direct_cmd寄存器，操作SDRAM进行对应操作。通过向memc_cmd寄存器写入状态模式命令，使DRAM控制器进入对应的工作模式。例如：向direct_cmd寄存器写入：Prechargeall’，‘Autorefresh’，‘NOP’，and ‘MRS’ 等命令，可以让SDRAM芯片分别执行不同操作，向memc_cmd寄存器写入一些状态命令可以让SDRAM芯片进入’Config’, ‘Ready’, and ‘Low_power’等工作模式。

DRAM控制器支持两种节能模式。当SDRAM处于不活动状态并且持续一定的时钟周期时，DRAM控制器会自动将SDRAM进入预充电节能模式或正常节能模式下以降低系统功耗。当驱动操作DRAM控制器进入对应的STOP（停止），Deep Stop（深度睡眠），Sleep Mode（睡眠）等模式时，SDRAM芯片进入自刷新的节能模式。

l 支持SDR SDRAM，Mobile SDR SDRAM，DDR SDRAM和Mobile DDR SDRAM类型芯片

l 支持两个内存芯片

l 支持64位的AMBA AXI总线类型

l 支持16位、64位内存总线

n 存储器接口1：支持16位DDR SDRAM和Mobile DDR SDRAM类型芯片

支持32位DDR SDRAM，Mobile DDR SDRAM，Mobile SDR SDRAM和SDR SDRAM类型芯片

不支持16位Mobile SDR SDRAM和SDR SDRAM类型芯片

l 地址空间：存储器接口1支持最多2Gb地址空间

l 支持正常节能模式和预充电的节能模式

l 数据传输低延迟特性

l 外部存储器总线优化

l 通过设置SFR寄存器支持选择外部存储器选型

l 通过SFR寄存器配置存储器的时序

l 支持扩展MRS指令集

l 工作电压：存储器接口1: 1.8V，2.5V

2. SDRAM类型内存接口

DRAM控制器支持最多两个相同类型的内存芯片，每个芯片最大容量256M。所有芯片共享相同引脚（时钟使能引脚和片选引脚除外），如表1-1所示给出了DRAM控制器的外部存储器引脚配置信息。

3. SDRAM初始化

在系统上电后，必须通过软件配置SDRAM接入DRAM控制器并且初始化DRAM控制器，下面给出DDR、MOBILE DDR SDRAM的初始化流程。

a) 向mem_cmd寄存器写入0b10，使其进入NOP工作状态

b) 向mem_cmd寄存器写入0b00，使其进入Prechargeall（整片预充电）工作状态

c) 向mem_cmd寄存器写入0b11，使其进入Autorefresh（自刷新）工作状态

d) 再次向mem_cmd寄存器写入0b11，使其进入Autorefresh（自刷新）工作状态

e) 向mem_cmd寄存器写入0b10，使其进入MRS工作状态，并且地址空间内的EMRS必须置位

f) 再次向mem_cmd寄存器写入0b10，使其进入MRS工作状态，并且地址空间内的MRS必须置位

4. DRAM寄存器

1) DRAM控制器状态寄存器（P1MEMSTAT）

P1MEMSTAT	位	描述	初始值
保留	[31:9]	-	-
芯片数量	[8:7]	内存控制器支持的芯片最大数量： 01 = 2片 6410只支持2片芯片，初始化为只读的01	01
芯片类型	[6:4]	内存控制器支持的芯片类型： 100 = MSDR/SDR/MDDR/DDR中任一类型	100
芯片位宽	[3:2]	接入内存芯片的位宽： 00 = 16位 01 = 32位 10 = 保留 11 = 保留	01
控制器状态	[1:0]	DRAM控制器状态： 00 = Config配置状态 01 = Ready就绪状态 10 = Pause暂停状态 11 = Low-Power节能状态	00

实际上，读到的有用信息就是Controller Status和Memory width。

2) DRAM控制器命令寄存器（P1MEMCCMD）

P1MEMCCMD

位

描述

初始值

保留

[31:3]

未定义，写入0

Memc_cmd

[2:0]

设置内存控制器的工作状态：

000 = Go

001 = sleep

010 = wakeup

011 = Pause

100 = Configure

101~111 = 保留

最开始应该配置为0x4，是处于Configure状态。在配置完所有的DRAM之后，将该寄存器设置为0x0，处于运行状态。

3) 直接命令寄存器（P1DIRECTCMD）

P1DIRECTCMD	位	描述	初始值
保留	[31:23]	未定义，写入0
扩展内存命令	[22]	（见下表）
芯片号	[21:20]	映射到外部存储芯片地址的位
命令	[19:18]	具体命令（见下表）
Bank地址	[17:16]	当以MRS或EMRS命令访问时，映射到外部存储器的Bank地址位
	[15:14]	未定义，写入0
地址线0~13	[13:0]	当以MRS或EMRS命令访问时，映射到外部存储器的内存地址位

用于发送命令到DRAM和访问DRAM中的MRS和EMRS寄存器。通过该寄存器初始化DRAM，先设置为NOP模式，然后设置为PrechargeAll进行充电，然后设置EMRS和MRS寄存器，一般是这么一个流程。具体的要参见你所使用的DRAM的datasheet。

4) 内存配置寄存器（P1MEMCFG）

P1MEMCFG	位	描述	初始值
保留	[31:23]	未定义
启动芯片	[22]	使能下面数量的芯片开始执行刷新操作： 00 = 1芯片 01 = 2芯片 10/11 = 保留	00
QoS master位	[20:18]	设置QoS值： 000 = ARID[3:0] 001= ARID[4:1] 010 = ARID[5:2] 011 = ARID[6:3] 100 = ARID[7:4] 101~111 = 保留	000
内存突发访问	[17:15]	在内存读写时，设置突发访问数据的数量： 000 = 突发访问1个数据 001 = 突发访问2个数据 010 = 突发访问4个数据 011 = 突发访问8个数据 100 = 突发访问16个数据 101~111 = 保留该值必须通过DIRECTORYCMD寄存器，写入到内存的模式寄存器中，并且数据必须匹配	010
Bank地址	[17:16]	当以MRS或EMRS命令访问时，映射到外部存储器的Bank地址位
Stop_mem_clock	[14]	当停止芯片时钟，不允许访问内存数据时，置位	0
自动节能	[13]	当该位置位时，芯片自动进入节能状态	0
关闭芯片延迟时间	[12:7]	当关闭内存芯片时，延迟的时钟个数	000000
自动预充电位	[6]	内存地址中自动预充电位的位置： 0 = ADDR[10] 1 = ADDR[8]	0
行地址位数	[5:3]	AXI地址线上的行地址位数： 000 = 11位 001 = 12位 010 = 13位 011 = 14位 100 = 15位 101= 16位	100
列地址位数	[2:0]	AXI地址线上的列地址位数： 000 = 8位 001 = 9位 010 = 10位 011 = 11位 100 = 12位	000

参考DRAM的datasheet。

5) 内存刷新时间寄存器（P1REFRESH）

P1REFRESH	位	描述	初始值
	[31:15]	-
刷新时间	[14:0]	内存刷新时钟周期数	0xA60

6) CAS 延迟寄存器（P1CASLAT）

P1CASLAT	位	描述	初始值
	[31:4]	-	-
CAS延迟	[3:1]	列地址选通延迟内存时钟周期数	0xA60
CAS HALF周期	[0]	设置CAS延迟数是否为半个内存时钟周期 0 = 以[3:1]设置数为CAS延迟时钟周期 1 = 以[3:1]设置数的一半为CAS延迟时钟周期	0

参考DRAM的datasheet。

下面13个寄存器用于DRAM操作中所需时间和延时寄存器，具体可以参考PL340文档。

7) T_DQSS寄存器（P1T_DQSS）

P1T_DQSS	位	描述	初始值
	[31:2]	-	-
t_DQSS	[1:0]	写入DQS的时钟周期	1

8) T_MRD寄存器（P1T_MRD）

P1T_MRD	位	描述	初始值
	[31:7]	-	-
t_ MRD	[6:0]	设置模式寄存器命令时间（内存时钟周期为单位）	0x02

9) T_RAS寄存器（P1T_RAS）

P1T_RAS	位	描述	初始值
	[31:4]	-	-
t_RAS	[3:0]	设置行地址选通到预充电操作延迟时间（内存时钟周期为单位）	0x7

10) T_RC寄存器（P1T_RC）

P1T_RC	位	描述	初始值
	[31:4]	-	-
t_RC	[3:0]	设置激活内存Bank x到激活另外一个Bank x操作的延迟时间（内存时钟周期为单位）	0xB

11) T_RCD寄存器（P1T_RCD）

P1T_RCD	位	描述	初始值
	[31:6]	-	-
Scheduled_RCD	[5:3]	设置t_RCD-3	011
t_RCD	[2:0]	设置RAS到CAS操作的最小延迟时间（内存时钟周期为单位）	101

12) T_RFC寄存器（P1T_RFC）

P1T_RFC	位	描述	初始值
	[31:10]	-	-
Scheduled_RFC	[9:5]	设置t_RFC-3	0x10
t_RFC	[4:0]	设置自动刷新命令操作延迟时间（内存时钟周期为单位）	0x12

13) T_RP寄存器（P1T_RP）

P1T_RP	位	描述	初始值
	[31:6]	-	-
Scheduled_RP	[5:3]	设置t_RP-3	011
t_RFC	[2:0]	设置预充电到RAS操作的延迟时间（内存时钟周期为单位）	101

14) T_RRD寄存器（P1T_RRD）

P1T_ RRD	位	描述	初始值
	[31:4]	-	-
t_RRD	[3:0]	设置激活内存Bank x到激活内存Bank y操作的延迟时间（内存时钟周期为单位）	0x2

15) T_WR寄存器（P1T_WR）

P1T_ WR	位	描述	初始值
	[31:3]	-	-
t_WR	[2:0]	设置写入数据到预充电操作的延迟时间（内存时钟周期为单位）	011

16) T_WTR寄存器（P1T_WTR）

P1T_ WTR	位	描述	初始值
	[31:3]	-	-
t_WTR	[2:0]	设置写入数据到读取数据操作的延迟时间（内存时钟周期为单位）	011

17) T_XP寄存器（P1T_XP）

P1T_ XP	位	描述	初始值
	[31:8]	-	-
t_XP	[7:0]	设置退出关闭电源命令的延迟时间（内存时钟周期为单位）	0x1

18) T_XSR寄存器（P1T_XSR）

P1T_ XSR	位	描述	初始值
	[31:8]	-	-
t_XSR	[7:0]	设置退出自刷新命令的延迟时间（内存时钟周期为单位）	0xA

19) T_ESR寄存器（P1T_ESR）

P1T_ ESR	位	描述	初始值
	[31:8]	-	-
t_ESR	[7:0]	设置自刷新命令的延迟时间（内存时钟周期为单位）	0x14

内存初始化代码：

（开发环境为ADS1.2）

MEM_SYS_CFG EQU 0x7e00f120
DMC1_BASE EQU 0x7e001000
INDEX_DMC_MEMC_STATUS EQU 0x0
INDEX_DMC_MEMC_CMD EQU 0x4
INDEX_DMC_DIRECT_CMD EQU 0x08
INDEX_DMC_MEMORY_CFG EQU 0x0c
INDEX_DMC_REFRESH_PRD EQU 0x10
INDEX_DMC_CAS_LATENCY EQU 0x14
INDEX_DMC_T_DQSS EQU 0x18
INDEX_DMC_T_MRD EQU 0x1c
INDEX_DMC_T_RAS EQU 0x20
INDEX_DMC_T_RC EQU 0x24
INDEX_DMC_T_RCD EQU 0x28
INDEX_DMC_T_RFC EQU 0x2c
INDEX_DMC_T_RP EQU 0x30
INDEX_DMC_T_RRD EQU 0x34
INDEX_DMC_T_WR EQU 0x38
INDEX_DMC_T_WTR EQU 0x3c
INDEX_DMC_T_XP EQU 0x40
INDEX_DMC_T_XSR EQU 0x44
INDEX_DMC_T_ESR EQU 0x48
INDEX_DMC_MEMORY_CFG2 EQU 0x4C
INDEX_DMC_CHIP_0_CFG EQU 0x200
INDEX_DMC_CHIP_1_CFG EQU 0x204
INDEX_DMC_CHIP_2_CFG EQU 0x208
INDEX_DMC_CHIP_3_CFG EQU 0x20C
INDEX_DMC_USER_STATUS EQU 0x300
INDEX_DMC_USER_CONFIG EQU 0x304
AREA LOW_INIT, CODE, READONLY
ENTRY
EXPORT mem_init
mem_init
ldr r0, =MEM_SYS_CFG ;Memory sussystem address 0x7e00f120
mov r1, #0xd ;Xm0CSn2 = NFCON CS0 设置NAND Flash为存储器
str r1, [r0]
ldr r0, =DMC1_BASE ;DMC1 base address 0x7e001000
; memc_cmd : 010 wake up
; 唤醒内存
ldr r1, =0x04
str r1, [r0, #INDEX_DMC_MEMC_CMD]
; Refresh period = ((Startup_HCLK / 1000 * DDR_tREFRESH) - 1) / 1000000 -> DDR_tREFRESH 7800 ns
; HCLK = 133MHz
; DDR内存规格规定，电容的电荷存储上限时间为64ms，而刷新操作每次是针对
; 一行进行的，即每一行的刷新时间为64ms，而内存芯片中一定数量的行
; 以L-Bank表示（见内存工作原理与物理特性），每个L-Bank有8192行（见内存硬件手册）
; 因此对L-Bank的刷新操作应该在64ms /8192 = 7813us时间内进行一次
; 而MDDR工作在133MHz时，其一个时钟周期为1/133M，那么一次L-Bank刷新
; 时间需要7.8us/1/133M个时钟周期，即有下面的公式：
; Refresh_Count = tREFRESH * HCLK(MHz)/1000
; tREFRESH = 7813 HCLK = 133 Refresh_Count = 1039
ldr r1, = 1039 ; DMC_DDR_REFRESH_PRD
str r1, [r0, #INDEX_DMC_REFRESH_PRD]
; CAS_Latency = DDR_CASL<<1 -> DDR_CASL 3
ldr r1, = 6 ; DMC_DDR_CAS_LATENCY
str r1, [r0, #INDEX_DMC_CAS_LATENCY]
; t_DQSS (clock cycles)
ldr r1, = 1 ; DMC_DDR_t_DQSS
str r1, [r0, #INDEX_DMC_T_DQSS]
; T_MRD (clock cycles)
ldr r1, = 2 ; DMC_DDR_t_MRD
str r1, [r0, #INDEX_DMC_T_MRD]
; T_RAS (clock cycles)
ldr r1, = 7 ; DMC_DDR_t_RAS
str r1, [r0, #INDEX_DMC_T_RAS]
; T_RC Active Bank x to Active Bank x delay(clock cycles)
ldr r1, = 10 ; DMC_DDR_t_RC
str r1, [r0, #INDEX_DMC_T_RC]
; T_RCD RAS to CAD delay(clock cycles)
ldr r1, = 4 ; DMC_DDR_t_RCD
ldr r2, = 8 ; DMC_DDR_schedule_RCD
orr r1, r1, r2
str r1, [r0, #INDEX_DMC_T_RCD]
; T_RFC AutoRefresh(clock cycles)
ldr r1, = 11 ; DMC_DDR_t_RFC
ldr r2, = 256 ; DMC_DDR_schedule_RFC
orr r1, r1, r2
str r1, [r0, #INDEX_DMC_T_RFC]
; T_RP Precharge to RAS delay(clock cycles)
ldr r1, = 4 ; DMC_DDR_t_RP
ldr r2, = 8 ; DMC_DDR_schedule_RP
orr r1, r1, r2
str r1, [r0, #INDEX_DMC_T_RP]
; T_RRD Active Bank x to Active Bank y delay(clock cycles)
ldr r1, = 3 ; DMC_DDR_t_RRD
str r1, [r0, #INDEX_DMC_T_RRD]
; T_WR Write to precharge delay(clock cycles)
ldr r1, =3 ; DMC_DDR_t_WR
str r1, [r0, #INDEX_DMC_T_WR]
; T_WTR Write to Read delay(clock cycles)
ldr r1, = 2 ;DMC_DDR_t_WTR
str r1, [r0, #INDEX_DMC_T_WTR]
; T_XP Exit Power down(clock cycles)
ldr r1, = 2 ; DMC_DDR_t_XP
str r1, [r0, #INDEX_DMC_T_XP]
; T_XSR Exit self refresh(clock cycles)
ldr r1, = 17 ; DMC_DDR_t_XSR
str r1, [r0, #INDEX_DMC_T_XSR]
; T_ESR SelfRefresh(clock cycles)
ldr r1, = 17 ; DMC_DDR_t_ESR
str r1, [r0, #INDEX_DMC_T_ESR]
; Memory Configuration Register
ldr r1, = 0x40010012 ; DMC1_MEM_CFG
str r1, [r0, #INDEX_DMC_MEMORY_CFG]
ldr r1, = 0xb41 ; DMC1_MEM_CFG2
str r1, [r0, #INDEX_DMC_MEMORY_CFG2]
ldr r1, = 0x150f8 ; DMC1_CHIP0_CFG
str r1, [r0, #INDEX_DMC_CHIP_0_CFG]
ldr r1, = 0 ; DMC_DDR_32_CFG
str r1, [r0, #INDEX_DMC_USER_CONFIG]
; The follows is according to the Datasheet initialization sequence
;DMC0 DDR Chip 0 configuration direct command reg
ldr r1, = 0x0c0000 ; DMC_NOP0
str r1, [r0, #INDEX_DMC_DIRECT_CMD]
;Precharge All
ldr r1, = 0 ; DMC_PA0
str r1, [r0, #INDEX_DMC_DIRECT_CMD]
;Auto Refresh 2 time
ldr r1, = 0x40000 ; DMC_AR0
str r1, [r0, #INDEX_DMC_DIRECT_CMD]
str r1, [r0, #INDEX_DMC_DIRECT_CMD]
;MRS
ldr r1, = 0xa0000 ; DMC_mDDR_EMR0
str r1, [r0, #INDEX_DMC_DIRECT_CMD]
;Mode Reg
ldr r1, = 0x80032 ; DMC_mDDR_MR0
str r1, [r0, #INDEX_DMC_DIRECT_CMD]
;Enable DMC1
mov r1, #0x0
str r1, [r0, #INDEX_DMC_MEMC_CMD]
check_dmc1_ready
ldr r1, [r0, #INDEX_DMC_MEMC_STATUS]
mov r2, #0x3
and r1, r1, r2
cmp r1, #0x1
bne check_dmc1_ready
nop
mov pc, lr
END

关键字：S3C6410 Tiny6410 Mini6410 MoblieDDR 内存驱动引用地址：S3C6410，Tiny6410，Mini6410，MoblieDDR内存驱动

上一篇：mini6410中断控制器-VIC中断控制器
下一篇：ARM系统中断产生流程

推荐阅读最新更新时间：2024-03-16 14:51

深入理解ARM体系架构（S3C6410）---UART实例

1、概括OVERVIEW S3C6410提供了4个独立的异步串行口，每个独立的串行口可以工作在中断模式或DMA模式下。也就是说UART能够产生一个中断或DMA请求。UART可以提供最高3Mbps。每个UART包含2个64位的FIFO，分别用于接收，发送缓冲。 S3C6410 UART 包括可编程的波特率，红外发射接收，1或2个停止校验位，5,6,7,8数据位，和奇偶检验。每个UART包含一个波特率发生器，接收发送和控制单元。波特率可以由PCLK，EXT_UCLK0或EX_UCLK1锁定。发送接收器分别包含了一个64位FIFO和一个数据移位器。通过向FIFO写入数据，再把FIFO中的数据拷贝到数据移位器中，从而通过TxD

[单片机]

深入理解ARM体系架构（<font color='red'>S3C6410</font>）---UART实例

linux-2.6.38到tiny6410的移植手册（连载3）__ LCD&触摸屏

这次lcd和触摸屏智能一起移植了，至于原因明天在开一贴详细说明， http://www.arm9home.net/read.php?tid-14273.html 主要是一线触摸的原因，它劫持了lcd的背光控制，这个花了我三天时间呀才发现，友善真是的。。。。先弄lcd屏吧 vi arch/arm/plat-samsung/include/plat/map-base.h 第39行增加 #define S3C_VA_LCD S3C_ADDR(0x01100000) /* LCD */ 从友善的源码中将arch/arm/mach-s3c64xx/include/mach/regs-lcd.h拷贝过来从友善的源码中将drive

[单片机]

linux-2.6.38到<font color='red'>tiny6410</font>的移植手册（连载3）__ LCD&触摸屏

s3c6410 系统时钟

----------------------------- 使用环境 PC: ubuntu 11.04 kernel: 2.6.32-28-generic corss: arm-linux-gcc 4.3.2 arm: s3c6410 ----------------------------- 系统时钟配置这篇主要介绍s3c6410在时钟设置上面是怎么处理的. 对于arm大家应该都不陌生,在使用的时候很多时候也非常关心主频是多少多少.经常听到的533Mhz 133Mhz 66Mhz 这些是比较典型的时钟频率了那么这些值是怎么来的,时钟源在选择的时候,又是通过哪些寄存器.怎么一步步的设置过来的呢. 今天就来解析arm

[单片机]

tiny6410 linux混杂设备 led驱动

#include linux/miscdevice.h #include linux/kernel.h #include linux/module.h #include linux/init.h #include linux/fs.h #include linux/types.h #include linux/errno.h #include linux/ioctl.h #include linux/cdev.h #include linux/device.h #include linux/ioport.h #include asm/io.h #include asm/uaccess.h #define

[单片机]

S3C6410开发(2)-构建开发环境

由于和之前的介绍的STM32在Ubuntu下的步骤相同所以在这篇中我们就不详细介绍了，只简单的说一下我们需要准备的东西。操作系统：Ubuntu16.04 LTS 编译工具链：gcc-arm-none-eabi 调试器：Jlink+openOCD 这里解释一下为什么是这些内容。操作系统就不说了这是我们开发的基础，工具链的选择也在上一篇中说明，因为我们目前开发的是裸机程序，所以不需要Linux版本，而其他网络上的编译器要不是商业收费的，要不就是被开发板商改过的旧版本。所以我们选择了到今天还在更新的gcc-arm-none-eabi，它目前的最新版本是5_4-2016q3，2016.9.26号放出的。至于为什么不用DNW或者

[单片机]

linux下的nandflash驱动分析（2）——基于s3c6410平台

1、在上一篇的probe函数中，在那个很大的for循环中出现了，对NAND的厂商，设备号，是MLC或SLC进行判断，这些是怎样进行的呢？其实这些都是在NAND芯片中定义的，我们只需按对应的时序读出这些信息，就可以进行判断，看下面这个图（摘于一个NAND芯片手册）： 2、上一篇中，nand_scan(s3c_mtd, 1)函数没有细说，这一篇说下这个函数，源码如下： /** * nand_scan - Scan for the NAND device * @mtd: MTD device structure * @maxchips: Number of chips to scan for * *

[单片机]

linux下的nandflash<font color='red'>驱动</font>分析（2）——基于<font color='red'>s3c6410</font>平台

s3c6410的RTC在linux中的驱动（1）

如果对RTC硬件不熟悉的话，可以看上面这篇博客，讲述了硬件有关的内容。 1、先从整体上做些分析，大致看了下linux2.6.28driversrtc文件中的kconfig和Makefile文件，在Makefile文件中有如下内容： ifeq ($(CONFIG_RTC_DEBUG),y) EXTRA_CFLAGS += -DDEBUG endif obj-$(CONFIG_RTC_LIB) += rtc-lib.o obj-$(CONFIG_RTC_HCTOSYS) += hctosys.o obj-$(CONFIG_RTC_CLASS) += rtc-core.o rtc-core-y := class.o inte

[单片机]

<font color='red'>s3c6410</font>的RTC在linux中的<font color='red'>驱动</font>（1）

基于S3C6410的视觉识别类人机器人控制系统设计

针对传统类人机器人在控制系统实时性和视觉识别方面的不足，以S3C6410作为主控芯片，设计了具有视觉识别功能的类人机器人控制系统，通过改进和简化视频识别算法取得了良好的目标识别效果。实验表明，基于本控制系统设计而成的类人机器人实时性好，目标识别准确，通过调整运动路径能够快速找到目标。智能移动机器人是近年来发展起来的一门综合学科，涉及机械设计、传感检测、人工智能等多方面知识。类人机器人的控制系统分为三个层次：最上层是机器人的策略规划层，利用各种算法实现各部分的功能；中间一层运行各类应用程序的嵌入式实时操作系统；最底层是硬件平台，通过外围获得各类数据、信息。自主机器人利用获取的信息控制机器人的动作。本文根据武术擂台机器人

[机器人]