单片机查表程序的用法

在单片机开发过程中.一些非线性的控制过程.最适合做一个表格来.时时改变系统的参数.达到控制的目的.最常的如产生正弦的的程.就是建一个大的数组时时改变输出的8位字节送给外部DA.由DA生成一个完整的正弦波.当然了.LED显示也是一个例子.通过建一个数组来实现段码的点亮点灭.下面就是一个LED表---digits[0]

#define SEG_a 0x01
#define SEG_b 0x02
#define SEG_c 0x04
#define SEG_d 0x08
#define SEG_e 0x10
#define SEG_f 0x20
#define SEG_g 0x40
#define SEG_dot 0x80
unsigned char digits[10] = {
 (SEG_a|SEG_b|SEG_c|SEG_d|SEG_e|SEG_f),   // 0
 (SEG_b|SEG_c),         // 1
 (SEG_a|SEG_b|SEG_d|SEG_e|SEG_g),    // 2
 (SEG_a|SEG_b|SEG_c|SEG_d|SEG_g),    // 3
 (SEG_b|SEG_c|SEG_c|SEG_f|SEG_g),    // 4
 (SEG_a|SEG_c|SEG_d|SEG_f|SEG_g),    // 5
 (SEG_a|SEG_c|SEG_d|SEG_e|SEG_f|SEG_g),   // 6
 (SEG_a|SEG_b|SEG_c),             // 7
 (SEG_a|SEG_b|SEG_c|SEG_d|SEG_e|SEG_f|SEG_g), // 8
 (SEG_a|SEG_b|SEG_c|SEG_d|SEG_f|SEG_g)  // 9
 };

C查表就太简单了temp2 = digits[ show_data[i] ];一句搞定,C中还有一个switch语句也是一个很好的用查表语句

C51汇编就相对麻烦一点.不过MCS-51指令系统中有专用的查表指令：MOVC A,@A+DPTR和MOV A,@A+PC.

segtab:

 dw 000ch
 dw 000ah
 dw 000ch ;0
 
 dw 000ch
 dw 0000h
 dw 0000h ;1
 
 dw 0008h
 dw 000eh
 dw 0004h ;2
 ......................

希望看了此文之后.大家对查表的一个清楚认识

MOVC A,@A+DPTR指令，DPTR作为基址寄存器时，其值为16位而且可根据需要设计，故可用于在64KROM范围内查表。编写查表程序时，首先把表的首址送入DPTR中，再将要查找的数据序号（或下表值）送入A中，然后就可以使用该指令进行查表操作，并将结果送累加器A中。 
MOVC A,@A+PC指令，PC作为基址寄存器时，其值由指令的位置确定，它只能设在查表指令操作码下的256个字节范围内。编写查表程序时，首先把查表数据的序号送入A中，再把从查表指令到表的首地址间的偏移量与A值相加，然后使用该指令进行查表操作，并把结果送累加器A中。

下面是把内部RAM 30H-37H单元中的十六进制数依次转换为ASCII码，并存入内部RAM 60H-6FH单元之中。用查表法编写程序。 
分析：由于十六进制数是从0～F，对应的ASCII码为30H～46H，每一个单元存放的16进制数，转换为ASCII码后分别存入2个单元，低位存低地址，高位存高地址。用ANL A ，#0FH 分别取高4位和低4位。 进行查表转换成相应的ASCII码。

MOVC  A , @A+DPTR 程序如下： 
ORG  0000H 
AJMP  MAININITIAL 
ORG  0050H 
MAININITIAL: ;给30H-37H赋初值 
MOV R0,#30H ;设置存数指针R0初值 
MOV R1,#00H ;设置赋值变量个数计数寄存器R1(循环计数器)初值 
MOV DPTR,#initialtab 
NEXTINITIAL: 
MOV A,R1 
MOVC A,@A+DPTR ;查表数据送累加器A 
MOV @R0,A 
INC R0 ;指针增一 
INC R1 ;循环计数器增一 
CJNE R1,#8,NEXTINITIAL ;判给30H-3FH赋初值完否 
MAIN: 
MOV R0,#30H ;设置十六进制数地址指针 
MOV R1,#60H ;设置ASCII码地址指针 
MOV R7,#08H ;需拼装的十六进制数字节个数 
MOV DPTR,#ACSIITAB 
ABC: 
MOV A,@R0 ;取十六进制数 
MOV B,A ;暂存 
ANL A,#0F0H ;取十六进制数的字节高4位 
RR A ;取十六进制数的字节高4位移到字节的低4位 
RR A 
RR A 
RR A 
MOVC A,@A+DPTR ;查表数据送累加器A 
MOV @R1,A ;保存转换结果 
INC R1 ;转换结果指针增一 
MOV A,B 
ANL A,#0FH ;取十六进制数的字节低4位 
MOVC A,@A+DPTR ;查表数据送累加器A 
MOV @R1,A ;保存转换结果 
INC R1 ;转换结果指针增一 
INC R0 ;转换数据指针增一 
DJNZ R7,ABC ;继续 
SJMP $

initialtab: ;给30H-37H赋值用初值表 
DB 23H,6DH,09H,7FH,8CH,1EH,4BH,5AH

ACSIITAB: ;0～F，对应的ASCII码表 
DB "012345678" 
DB "9ABCDEF"

END

MOVC A,@A+PC程序如下： 
ORG 0000H 
AJMP MAININITIAL 
ORG 0050H 
MAININITIAL: ;给30H-37H赋初值 
MOV R0,#30H ;设置存数指针R0初值 
MOV R1,#00H ;设置赋值变量个数计数寄存器R1(循环计数器)初值 
MOV DPTR,#initialtab 
NEXTINITIAL: 
MOV A,R1 
MOVC A,@A+DPTR ;查表数据送累加器A 
MOV @R0,A 
INC R0 ;指针增一 
INC R1 ;循环计数器增一 
CJNE R1,#8,NEXTINITIAL ;判给30H-3FH赋初值完否 
MAIN: 
MOV R0,#30H ;设置十六进制数地址指针 
MOV R1,#60H ;设置ASCII码地址指针 
MOV R7,#08H ;需拼装的十六进制数字节个数 
MOV DPTR,#ACSIITAB 
ABC: 
MOV A,@R0 ;取十六进制数 
MOV B,A ;暂存 
ANL A,#0F0H ;取十六进制数的字节高4位 
RR A ;取十六进制数的字节高4位移到字节的低4位 
RR A 
RR A 
RR A 
ACALL TRANACSAII ;查表数据送累加器A 
MOV @R1,A ;保存转换结果 
INC R1 ;转换结果指针增一 
MOV A,B 
ANL A,#0FH ;取十六进制数的字节低4位 
ACALL TRANACSAII ;查表数据送累加器A 
MOV @R1,A ;保存转换结果 
INC R1 ;转换结果指针增一 
INC R0 ;转换数据指针增一 
DJNZ R7,ABC ;继续 
SJMP $

initialtab: ;给30H-37H赋值用初值表 
DB 23H,6DH,09H,7FH,8CH,1EH,4BH,5AH

TRANACSAII: 
INC A ;查表之前A加1是因为MOVC指令与数据表之间有一个地址单元的间隔(RET指令) 
MOVC A,@A+PC ;由于数据表紧跟MOVC指令之后,因此以PC作为基址寄存器比较方便. 
RET 
ACSIITAB: ;0～F，对应的ASCII码表 
DB "012345678" 
DB "9ABCDEF"

end

其它单片机跟C51查表类似.下面介绍松翰的单片机的查表程序.松翰单片机查表是通过X.Y寄存器来达到指向的表的目的如下

 b0mov z,#segtab$L
 b0mov y,#segtab$M
 b0mov a,freqh  ;led 3

 add z,a
 b0bts0 fc
 incms y;表加1
 nop
 movc