2440的控制器拾遗

说白了 2440的控制器可以理解为stm32里面的FMSC 大同小异

可以外部寻址1GB的范围。是CPU和外部外设通讯的中间总线装置。 

例如网卡 SDRAM扩展串口等都是通过这个控制器去连接CPU

现在开始学习SDRAM的内容

SDRAM 我们用的是EM63A165TS

1. NOR FLASH 和 NAND FLASH 程序启动方式

当用nor Flash的时候：0 地址是指向nor flash 里面读取指令

当用nand flash的的时候： 会把nand flash的前4K的代码复制到内部4k内存里面

在2440里面 bank 7和bank6必须大小相等

bank1 的大小因为是连接在boot引脚上 所以需要用硬件（OM1 和OM2 引脚去调节 位宽）

BWSCON:  每四个位控制一个bank 最高4位对应bank7 

（1）。 STx：设置启动禁止SDRAM 的数据掩码引脚 对于SDRAM 这个位应该是0 对于SRAM应该是1

（2）。WSx：是否使用储存器Wait信号

（3）DWx： 使用bank的位宽 

在这里 我们的SDRAM连到了BANK6 （CS6）

其中 UB/LB 是表示高8位和低8位

Bank6的起始地址是0x3000_000

BANKCONx:

控制BANK0~BANK5 外接设备的访问时序， 使用默认的0x0700 

控制BANK6~BANK7：（1） BANK MT（[15:16]）但是为00 的时候是SRAM 11的时候是SDRAM

当设置成00 的时候 后面的设置和Bank0~bank5 的设置一样

当设置成01的时候：

Trcd[3:2]: RAS to CAS delay 行到列之间的延迟 应该设置为1

SCAN【1:0】： SDRAM的列地址位数 （本芯片是9位）所以是01

REFRESH：

SDRAM必须开启刷新功能

22位： 自动刷新

21位： 0

20:0

19:18： 默认值11

10:0：( 2^11 - refresh_count+1)/HCLK

BANKSIZE: 

7: 突发传输

6： 使用SCKE令SDRAM进入省电模式

4： 尽在访问SDRAM的时候发出SCLK信号

2:0： bank6/7的大小是可以变化的 这里是64MB

这就是设置的方法 

程序：

@*************************************************************************

@ File：head.S

@ 功能：设置SDRAM，将程序复制到SDRAM，然后跳到SDRAM继续执行

@*************************************************************************     

.equ        MEM_CTL_BASE,      0x48000000

.equ        SDRAM_BASE,        0x30000000

.text

.global _start

_start:

    bl  disable_watch_dog              @ 关闭WATCHDOG，否则CPU会不断重启

    bl  memsetup                        @ 设置存储控制器

    bl  copy_steppingstone_to_sdram    @ 复制代码到SDRAM中

    ldr pc, =on_sdram                  @ 跳到SDRAM中继续执行

on_sdram:

    ldr sp, =0x34000000                @ 设置堆栈  因为makefile里面一开始指向的是300000 前面的几                                                               行都是占用堆栈的（每条指令+4）。。所以这里的指针指向的  是main的地址。  内存是64MB所以是栈顶 

    bl  main

halt_loop:

    b  halt_loop

disable_watch_dog:

    @ 往WATCHDOG寄存器写0即可

    mov r1,    #0x53000000

    mov r2,    #0x0

    str r2,    [r1]

    mov pc,    lr      @ 返回

copy_steppingstone_to_sdram:

    @ 将Steppingstone的4K数据全部复制到SDRAM中去

    @ Steppingstone起始地址为0x00000000，SDRAM中起始地址为0x30000000

    mov r1, #0

    ldr r2, =SDRAM_BASE

    mov r3, #4*1024

1: 

    ldr r4, [r1],#4    @ 从Steppingstone读取4字节的数据，并让源地址加4

    str r4, [r2],#4    @ 将此4字节的数据复制到SDRAM中，并让目地地址加4

    cmp r1, r3          @ 判断是否完成：源地址等于Steppingstone的未地址？

    bne 1b              @ 若没有复制完，继续

    mov pc,    lr      @ 返回

memsetup:

    @ 设置存储控制器以便使用SDRAM等外设

    mov r1,    #MEM_CTL_BASE      @ 存储控制器的13个寄存器的开始地址

    adrl    r2, mem_cfg_val        @ 这13个值的起始存储地址

    add r3,    r1, #52            @ 13*4 = 54

1: 

    ldr r4,    [r2], #4            @ 读取设置值，并让r2加4

    str r4,    [r1], #4            @ 将此值写入寄存器，并让r1加4

    cmp r1,    r3                  @ 判断是否设置完所有13个寄存器

    bne 1b                          @ 若没有写成，继续

    mov pc,    lr                  @ 返回

.align 4

mem_cfg_val:

    @ 存储控制器13个寄存器的设置值

    .long  0x22011110      @ BWSCON

    .long  0x00000700      @ BANKCON0

    .long  0x00000700      @ BANKCON1

    .long  0x00000700      @ BANKCON2

    .long  0x00000700      @ BANKCON3 

    .long  0x00000700      @ BANKCON4

    .long  0x00000700      @ BANKCON5

    .long  0x00018005      @ BANKCON6

    .long  0x00018005      @ BANKCON7

    .long  0x008C07A3      @ REFRESH

    .long  0x000000B1      @ BANKSIZE

    .long  0x00000030      @ MRSRB6

    .long  0x00000030      @ MRSRB7