51单片机驱动16×16LED点阵显示动画汉字汇编程序-电子工程世界

分享到: 微博; QQ; 微信; LinkedIn

电路图就不贴出来了16×16LED点阵的典型接法。这里提供一个完整的AT89S51单片机驱动驱动led点阵显示具有动画效果的汉字的汇编程序列子.

         ORG 0000H
ST:      MOV A,#0FFH ;初始化
         MOV P1,A
         MOV P2,A
         MOV P3,A
         MOV P0,A
         CLR A
         MOV R0,#50H ;显示缓存清0
         MOV R1,#20H ;控制清0的次数
ST0:     MOV @R0,A
         INC R0
         DJNZ R1,ST0

;正文显示
CHINESE: MOV DPTR,#TAB1 ;查表指针指向TAB1
         LCALL HZ
;结束动画
SCREE:
         MOV DPTR,#TAB2;查表指针指向TAB2
         ACALL DD
         MOV DPTR,#TAB3;查表指针指向TAB3
         ACALL DD
         MOV DPTR,#TAB4;查表指针指向TAB4
         ACALL DD
         LJMP CHINESE
;显示8幅画面子程序,SCREE专用,用字模软件字要倒置（表必须深256字节）
DD:      MOV B,#00H
         MOV R0,#08H ;显示8幅画面
         AJMP CC
CC0:     MOV A,B
         ADD A,#20H   ;指向下一幅画面
         MOV B,A
CC:      MOV R7,#08H ;画面停留时间
         MOV R3,B
         MOV 37H,R0
         LCALL ENTER
DIS00:   LCALL DISPLAY
         DJNZ R7,DIS00
         MOV R0,37H
         DJNZ R0,CC0
         RET
;汉字上移子程序，可显示8个汉字，（表必须深256字节）
HZ:      MOV R3,#00H ;查表偏移量
         MOV R5,#81H ;查表128次
MOVBACK: MOV R4,#10H ;使显示完一个汉字
MOVBACK0: MOV R7,#02H ;一桢画面显示时间
         MOV R0,#6DH ;低8位R0指向显示缓存倒数第3个字节，以备与最后1个字节交换
         MOV R1,#6CH ;高8位R1指向显示缓存倒数第4个字节，以备与倒数第2个字节交换
         MOV R2,#10H ;内存后移的次数
         DJNZ R5,MOVBACK1
         RET           ;显示完该表，返回
MOVBACK1: MOV A,@R0 ;低8位被后移的内存单元数据暂存入A
         INC R0     ;后移两字节
         INC R0
         MOV @R0,A ;放入要移的低8位数据
         MOV A,R0   ;R0指向下一个要后移的内存单元
         SUBB A,#04H
         MOV R0,A
         MOV A,@R1 ;高8位被后移的内存单元数据暂存入A
         INC R1     ;后移两字节
         INC R1
         MOV @R1,A ;放入要移高8位的数据
         MOV A,R1   ;R1指向下一个要后移的内存单元
         SUBB A,#04H
         MOV R1,A   ;R1指向下一个要后移的内存单元
         DJNZ R2,MOVBACK1 ;显示缓存数据依次后移
         MOV A,R3   ;从表TAB1读入要移进50H,51H的数据
         MOVC A,@A+DPTR;先给50H读数据
         MOV 50H,A
         MOV A,R3    ;指向下一字节
         INC A
         MOV R3,A
         MOVC A,@A+DPTR;再给51H读数据
         MOV 51H,A
         MOV A,R3    ;指向下一字节
         INC A
         MOV R3,A
         MOV 30H,R3 ;保护数据
         MOV 31H,R4
         MOV 32H,R5
DISMOV: LCALL DISPLAY ;显示当前数据
         DJNZ R7,DISMOV
         MOV R3,30H
         MOV R4,31H
         MOV R5,32H
         DJNZ R4,MOVBACK0
         MOV 30H,R3   ;保护数据
         MOV 32H,R5
         MOV R7,#24H ;显示当前数据延时
DISMOV0: LCALL DISPLAY
         DJNZ R7,DISMOV0
         MOV R3,30H
         MOV R5,32H
         LJMP MOVBACK
;放进一幅显示数据到显示缓存子程序，要先设好指针DPTR和R3,影响R1,R2,R3
ENTER:   MOV R1,#50H ;从50H单元起把表存入
         MOV R2,#20H ;查表次数
         MOV A,R3
CLLOOP_: MOVC A,@A+DPTR ;查表
         MOV @R1,A    ;将表放进5X,6X单元
         INC R1       ;R1指向下一个地址空间
         MOV A,R3     ;查表指针后移
         INC A
         MOV R3,A     ;将指针修改结果存入R3
         DJNZ R2,CLLOOP_;没查完转CLLOOP_
         RET
;15MS,显示子程序,一桢32个字节,影响A,R0,R1,R3,R4,R5,R6;
;http://www.51hei.com单片机网提供汉字取模工具，可显示任意汉字
DISPLAY: MOV A,#0FFH
         MOV P0,A
         MOV P1,A
         MOV P2,A
         MOV P3,A
         SETB C
         MOV R6,#7FH ;赋扫描字初值,左移后初值为0FEH
         MOV R5,#00H ;列扫描低8位控制
         MOV R0,#50H ;行的高8(p1)位要显示的数据起始地址
         MOV R1,#10H ;扫描次数
DISLOOP: MOV A,@R0    ;从内存读数据
         MOV P2,#0FFH ;装入数据时不显示任何东西
         MOV P3,#0FFH
         CPL A        ;数据取反以适合显示
         MOV P1,A     ;送入行的高8(p1)位要显示的数据
         INC R0       ;修改R0指向低8位要显示的数据
         MOV A,@R0    ;读低8位要显示的数据
         CPL A        ;数据取反以适合显示
         MOV P0,A     ;送入行的低8(p0)位要显示的数据
         INC R0       ;R0指向下一个高8(p0)位要显示的数据
         LCALL NEXT     ;调用列扫描程序
         LCALL DELAY1MS ;显示延时
         DJNZ R1,DISLOOP;一桢显示完返回
         MOV P3,#0FFH ;全灭
         RET
;列扫描子程序DISLOOP专用
NEXT:    JNC NEXT1    ;C=0转扫描高8(p3)位行
         MOV A,R6     ;修改扫描字
         RL   A
         MOV R6,A
         INC R5
         CJNE R5,#09H,NEXT0 ;R6=#0FEH时C=0
         AJMP NEXT1
BACK:    RET
NEXT0:   MOV P2,R6    ;扫描低8(p2)位行
         AJMP BACK
NEXT1:   MOV P2,#0FFH
         MOV P3,R6    ;扫描高8(p3)位行
         MOV A,R6     ;修改扫描字
         RL   A
         MOV R6,A
         AJMP BACK
;延时1MS子程序
DELAY1MS: MOV R3,#10
D0:      MOV R4,#50
D1:      DJNZ R4,D1
         DJNZ R3,D0
         RET[page]

TAB1:
DB 01FH,0F8H,001H,000H,07FH,0FEH,041H,004H,01DH,070H,001H,000H,01DH,070H,000H,000H
DB 01FH,0F0H,011H,010H,01FH,0F0H,011H,010H,01FH,0F2H,001H,002H,001H,002H,000H,0FEH;電
DB 000H,000H,03FH,0F0H,000H,020H,000H,040H,000H,080H,001H,000H,001H,000H,001H,004H
DB 0FFH,0FEH,001H,000H,001H,000H,001H,000H,001H,000H,001H,000H,005H,000H,002H,000H;子
DB 008H,000H,008H,0FCH,07EH,084H,008H,084H,0FFH,094H,041H,088H,022H,080H,014H,0FEH
DB 07EH,0A4H,008H,0A4H,008H,098H,0FFH,098H,008H,0A4H,008H,0A6H,008H,0C4H,008H,080H;報
DB 000H,000H,000H,010H,03FH,0F8H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H
DB 000H,000H,000H,000H,000H,000H,000H,004H,07FH,0FEH,000H,000H,000H,000H,000H,000H;二
DB 01FH,0F8H,001H,000H,07FH,0FEH,041H,004H,01DH,070H,001H,000H,01DH,070H,002H,080H
DB 004H,060H,01AH,01EH,0E1H,008H,01FH,0E0H,000H,040H,002H,080H,001H,000H,001H,000H;零
DB 01FH,0F8H,001H,000H,07FH,0FEH,041H,004H,01DH,070H,001H,000H,01DH,070H,002H,080H
DB 004H,060H,01AH,01EH,0E1H,008H,01FH,0E0H,000H,040H,002H,080H,001H,000H,001H,000H;零
DB 004H,000H,003H,000H,001H,080H,001H,000H,0FFH,0FEH,000H,000H,000H,000H,004H,080H
DB 006H,040H,004H,020H,008H,010H,008H,018H,010H,00CH,020H,00CH,040H,008H,000H,000H;六
DB 000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H
DB 000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H;(空)

;结束动画
;-- 水纹 -- ** 宋体, 12 **
; 当前所选字体下一个汉字对应的点阵为: 宽度x高度=128x16, 调整后为: 128x16
TAB2:DB 000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,001H,080H
DB 001H,080H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H
DB 000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,001H,080H,003H,0C0H
DB 003H,0C0H,001H,080H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H,000H
DB 000H,000H,000H,000H,000H,000H,000H,000H,001H,080H,002H,040H,004H,020H,008H,010H
DB 008H,010H,004H,020H,002H,040H,001H,080H,000H,000H,000H,000H,000H,000H,000H,000H
DB 000H,000H,001H,0C0H,006H,030H,008H,008H,008H,008H,010H,004H,020H,002H,020H,002H
DB 020H,002H,010H,004H,008H,008H,008H,008H,006H,030H,001H,0C0H,000H,000H,000H,000H
DB 003H,0C0H,00CH,030H,010H,008H,010H,008H,060H,006H,040H,002H,080H,001H,080H,001H
DB 080H,001H,080H,001H,040H,002H,060H,006H,010H,008H,010H,008H,00CH,030H,003H,0C0H
DB 000H,000H,038H,01CH,046H,062H,081H,081H,080H,001H,040H,002H,040H,002H,020H,004H
DB 020H,004H,040H,002H,040H,002H,080H,001H,081H,081H,046H,062H,038H,01CH,000H,000H
DB 0C0H,003H,0A0H,005H,058H,01EH,024H,024H,024H,024H,01EH,078H,005H,0A0H,002H,040H
DB 002H,040H,005H,0A0H,01AH,078H,024H,024H,024H,024H,058H,01AH,0A0H,005H,0C0H,003H
DB 000H,000H,0C0H,003H,0B0H,00DH,088H,011H,044H,022H,025H,0A4H,012H,048H,00DH,0B0H
DB 00DH,0B0H,012H,048H,025H,0A4H,044H,022H,088H,011H,0B0H,00DH,0C0H,003H,000H,000H
;--福-- ** 宋体, 12 **
; 当前所选字体下一个汉字对应的点阵为: 宽度x高度=16x16, 调整后为: 16x16
TAB3:DB 0AAH,055H,055H,0AAH,0AAH,055H,055H,0AAH,0AAH,055H,055H,0AAH,0AAH,055H,055H,0AAH
DB 055H,0AAH,0AAH,055H,055H,0AAH,0AAH,055H,055H,0AAH,0AAH,055H,055H,0AAH,0AAH,055H
DB 0AAH,055H,055H,0AAH,0AAH,055H,055H,0AAH,0AAH,055H,054H,02AH,0A8H,015H,050H,00AH
DB 050H,00AH,0A8H,015H,054H,02AH,0AAH,055H,055H,0AAH,0AAH,055H,055H,0AAH,0AAH,055H
DB 0AAH,055H,054H,02AH,0A8H,015H,050H,00AH,0A0H,005H,040H,002H,080H,001H,000H,000H
DB 000H,000H,080H,001H,040H,002H,0A0H,005H,050H,00AH,0A8H,015H,054H,02AH,0AAH,055H
DB 0A0H,005H,040H,002H,091H,0F9H,000H,000H,074H,0F0H,019H,008H,031H,008H,058H,0F0H
DB 014H,000H,011H,0F8H,012H,044H,013H,0FCH,012H,044H,091H,0F9H,040H,002H,0A0H,005H
DB 020H,000H,013H,0FEH,010H,000H,0FDH,0FCH,005H,004H,009H,004H,011H,0FCH,030H,000H
DB 05BH,0FEH,096H,022H,012H,022H,013H,0FEH,012H,022H,012H,022H,013H,0FEH,012H,002H
DB 000H,004H,07FH,0C8H,000H,008H,03FH,0BFH,020H,0A0H,020H,090H,03FH,088H,000H,00CH
DB 07FH,0DAH,044H,069H,044H,048H,07FH,0C8H,044H,048H,044H,048H,07FH,0C8H,040H,048H
DB 010H,040H,010H,080H,091H,000H,073H,0FFH,014H,080H,018H,040H,040H,0FFH,05EH,092H
DB 052H,092H,052H,092H,052H,0FEH,052H,092H,052H,092H,05EH,092H,040H,0FFH,000H,000H
DB 012H,002H,013H,0FEH,012H,022H,012H,022H,013H,0FEH,012H,022H,096H,022H,05BH,0FEH
DB 030H,000H,011H,0FCH,009H,004H,005H,004H,0FDH,0FCH,010H,000H,013H,0FEH,020H,000H
TAB4:DB 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0F8H,0FFH,0F8H,0FFH,0C0H,0FFH,0C0H
DB 0FEH,000H,0FEH,000H,0F0H,000H,0F0H,007H,0B0H,002H,0C8H,002H,048H,006H,030H,002H;STEP1
DB 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0F8H,0FFH,0F8H,0FFH,0C0H,0FFH,0C0H
DB 0FEH,000H,0FEH,000H,0F6H,000H,0F9H,007H,089H,002H,086H,001H,000H,005H,000H,002H;STEP2
DB 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0F8H,0FFH,0F8H,0FFH,0C0H,0FFH,0C0H
DB 0FEH,0C0H,0FFH,020H,0F1H,020H,0F0H,0C7H,080H,001H,080H,007H,000H,001H,000H,007H;STEP3
DB 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0F8H,0FFH,0F8H,0FFH,0D8H,0FFH,0E4H
DB 0FEH,024H,0FEH,018H,0F0H,000H,0F0H,001H,080H,001H,080H,007H,000H,005H,000H,005H;STEP4
DB 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FBH,0FFH,0FCH,0FFH,0C4H,0FFH,0C3H
DB 0FEH,000H,0FEH,000H,0F0H,000H,0F0H,007H,080H,001H,080H,007H,000H,004H,000H,007H;STEP5
DB 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,000H,000H,000H,000H,000H,000H
DB 000H,000H,000H,000H,000H,000H,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH
DB 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH
DB 0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH,0FFH
DB 000H,000H,0F4H,058H,084H,0D4H,085H,052H,0F5H,052H,085H,052H,086H,054H,0F4H,058H
DB 000H,000H,022H,05EH,022H,050H,022H,050H,023H,0DEH,022H,050H,022H,050H,0FAH,05EH
END

关键字：51单片机 16LED点阵动画汉字引用地址：51单片机驱动16×16LED点阵显示动画汉字汇编程序

上一篇：单片机红外遥控+步进电机+1602液晶显示c语言源程序
下一篇：基于单片机和FAT16的SD卡读写系统设计

推荐阅读最新更新时间：2024-03-16 13:14

深入理解51单片机串口通信及通信实例

　　串口通信的原理　　串口通信（SerialCommunications）的概念非常简单，串口按位（bit）发送和接收字节。尽管比按字节（byte）的并行通信慢，但是串口可以在使用一根线发送数据的同时用另一根线接收数据。它很简单并且能够实现远距离通信。比如IEEE488定义并行通行状态时，规定设备线总长不得超过20米，并且任意两个设备间的长度不得超过2米；而对于串口而言，长度可达1200米。典型地，串口用于ASCII码字符的传输。通信使用3根线完成，分别是地线、发送、接收。由于串口通信是异步的，端口能够在一根线上发送数据同时在另一根线上接收数据。其他线用于握手，但不是必须的。串口通信最重要的参数是波特率、数据位、停止位和奇偶校验

[单片机]

51单片机ADC0832电压测量液晶1602显示的C程序与proteus仿真

很早对AD转换感兴趣，也想自己业余做块单片机开发板，让广大的电子设计爱好者学习使用单片机。今天通过搜索，整理了proteus 7可以仿真通过的基于51单片机+ADC0832电压采集并通过液晶1602显示电压的C程序及电路连接图，希望对大家有所帮助。程序是谁写的谁修改的并不主要，主要的是学会并使用单片机AD转换，这才是王道。电路连接图如下： C程序如下： #include reg52.h #include intrins.h #include math.h /**********************************8/ /**********LCD1602接口程序*********

[单片机]

【51单片机】keil建立工程与烧录软件操作（1）

Keil建立工程 1.进入主界面 2.工程-新建μVision工程 3.选择设备。Atmel-AT89C52 4.新建空白页-C文件格式保存（.c） 5.双击源组-将C文件添加入源组 6.目标设置 Output-勾选Create HEX File（每个新工程都要勾选一遍）烧录软件操作 1.烧录前，连接好板子与电脑。（直接接到电脑USB接口上，不要接到集线器上）。打开烧录软件 2.查看usb串口号 3.选择单片机型号和本机USB串口号（串口号不一定） 4.选择刚编译好的程序 5.下载到单片机上

[单片机]

c51单片机中断函数

以串口中断为例：如： void serial() interrupt 4 { } 和 void serial_uart() interrupt 4 { } 两个函数的功能都是定义串口中断函数。函数名字不一样不重要，重要的是函数名字后面的interrupt 4（中断向量表地址）要正确。

[单片机]

51单片机计数器与定时器的区别

　　在51单片机的学习过程中，我们经常会发现中断、计数器/定时器、串口是学习单片机的难点，对于初学者来说，这几部分的内容很难理解。但是我个人觉得这几部分内容是单片机学习的重点，如果在一个学期的课堂学习或者自学中没有理解这几部分内容，那就等于还没有掌握51单片机，那更谈不上单片机的开发了，我们都知道在成品的单片机项目中，有很多是以这几部分为理论基础的，万年历是以定时器为主的，报警器是以中断为主的，联机通讯是以串口为主的。　　在这几部分内容中，计数器/定时器对于初学者说很容易搞混淆，下面我将对这方面的内容结合自己的学习经验谈几点看法。　　计数器和定时器的本质是相同的，他们都是对单片机中产生的脉冲进行计数，只不过计数器是单片机外部触

[单片机]

51单片机的内部结构和程序执行过程解析

注： 1.ROM：只读存储器，单片机的只读存储区大多用于存储程序固又称程序存储器。 51单片机是EPROM，所谓的EPROM是可擦除的只读存储器。可以把原来的程序擦除了，再写一个新的进去。断电后是可以保存的，数据存储器（RAM）是不能保存的。 RAM只能在程序执行的时候不断地重新存储定义的变量。如int x，int y 可以通过code这个指令来将定义的变量放在ROM，而不是RAM中，节省RAM资源 2.RAM：随机存取存储器，用于存储定义的变量等，速度快 51单片机的RAM存储容量远小于ROM，但是速度非常之快内部详细图示内部的结构看似十分复杂，但是大致上可以分为两个部分：运算器（红色框）和控制器（蓝色框）

[单片机]

51单片机PWM控制LED亮灭

设计思路：用定时器中断产生最小时间单位T0，每m个T0组成一个子周期 T10，其中前n个T0为LED导通时间，即Ton=n*T0,则Toff=(m-n)*T0 ;每X个T10组成一个母周期T20，其中前y个T10为有效控制时间，后续的（x-y)个T10令LED熄灭或者子周期占空比调至最小。 ;适当调节n/m和x/y的比例使显示效果达到最佳。 ;以下是刚刚调试通过的小段程序，显示效果良好。 ;实验过程本人有一种推测，不知是否成立: ;子周期的最小占空比的宽度应大于LED的点亮时间，即点亮LED的时间宽度n/m*T0应足够产生余辉。类似于动态数码管对点亮时间的要求。 ;母周期的宽度应小于1/50s，提高刷新频率以令肉眼察觉不出闪烁。

[单片机]

一种基于51单片机控制的数字视频混合器

近几年，数字电视技术发展很快，数字视频混合器可以将两路或多数数字视频信号按照一定的算法混合成一路或多路数字视频信号。作为数字视频信号的基本处理单元，该混合器在数字电视节目的编辑制作和播控传输系统中具有举足轻重的作用。本文介绍的基于单片机控制的数字视频键控混合器具有以下特点：内含两级串联的键控混合器，可以在主信号中键两入两路附加数字信号，如时钟台标或各种字幕标识；可以远程遥控，也可现场按键控制；可以随时更新和保存系统配置，改变系统功能和技术参数；该系统稳定可靠，对掉电、死机等异常现象有自复位能力。整个系统包括硬件和软件两部分，硬件包括数字混合部分和单片机控制部分。 1 数字混合部分输入的数字信号有背景信号、键控信号和填

[单片机]