【ARM裸机】 - 中断与异常

中断与异常

这节重点理解，对于一个CPU，如S3C2440，它的中断控制器所起的硬件作用，即当中断触发时，硬件本身会强迫CPU到异常向量表的地址处执行其中一条，这是硬件强行完成的跳转操作；之后跳转到中断处理程序，此部分由程序员来实现，一般需要做：1、保护现场 2、执行处理程序 3、回复现场。

理解中断带来的好处，节省了CPU资源，是操作系统中的基础。

  ARM的7中工作模式

  ARM的2种状态：ARM指令集与Thumb指令集的区别

1、中断控制器

一个事件的处理往往有两种方式：

中断方式

轮询方式

轮询方式比较简单，在死循环中没隔一定时间，进行一次判断事件是否发生，比较耗费资源。

中断方式相对复杂一点，但是节省资源，往往通过硬件触发中断，然后执行中断处理程序。

2、ARM中对异常的使用

（1）    软件初始化中断

设置中断源

设置中断控制器（屏蔽、优先级设置）

打开CPU中断总开关

（2）    产生中断

按下按键->中断控制器->CPU

（3）    触发中断流程（硬件自身具备）

CPU每执行完一条执行就检查是否有异常发生

发现异常产生，就去处理，对于不同的异常，跳转到不同的地址（即中断向量表）执行程序。

（4）    执行中断流程

中断发生时，硬件迫使CPU到异常向量表的指定位置去执行。此位置往往是一条跳转指令，跳转到中断处理程序的地方。

异常向量表：

按键中断发生时，CPU通过硬件被迫使到0x18的地址去执行，即ldr pc, _irq。

.globl _start

_start: b start_code

ldr pc, _undefined_instruction

ldr pc, _software_interrupt

ldr pc, _prefetch_abort

ldr pc, _data_abort

ldr pc, _not_used

ldr pc, _irq

ldr pc, _fiq

_irq中我们需要做：

保护现场

调用处理函数

恢复现场

3、CPU运行模式

（1）根据芯片手册知道，ARM920T 支持 7 种运行模式：

●  用户（usr） ）：正常 ARM 程序执行状态

●  快中断（fiq） ）：为支持数据传输或通道处理设计

●  中断（irq） ）：用于一般用途的中断处理

●  管理（svc） ）：操作系统保护模式

●  中止（abt ）: 数据或指令预取中止后进入

●  系统（sys） ）：操作系统的特权用户模式

●  未定义（und） ）：执行了一个未定义指令时进入

（2）7中模式对应的寄存器

R13：SP（堆栈指针）

R14：LR（保存了异常发生时的指令地址）

在不同工作模式下，有该模式专属的寄存器,如中断下的R13R14寄存器，处于中断模式时，此时的R13R14是此模式下专有的，不影响其他模式下的R13R14。

CPSR是程序状态寄存器[4:0]决定了工作模式，[27:8]是保留字节，[31:28]是条件代码标志位。如执行cmp R0，R1时，影响Z位，当R0=R1时，Z=1；否则Z=0；beq XXX，根据Z==1，则跳转到XXX。

CPSR：程序状态寄存器

SPSR：程序状态保存寄存器，用来保存被中断模式的CPSR。

位于模式的对应关系：

4、异常执行总结

保存与恢复现场

5、两种状态

ARM 状态：一条汇编对应机器码占4个字节

Thumb 状态：一条汇编对应机器码占2个字节

6、产生未定义指令异常的例子

.text

.global _start

_start:

b reset  /* vector 0 : reset */

b do_und /* vector 4 : und */

do_und:

/* 执行到这里之前:

* 1. lr_und保存有被中断模式中的下一条即将执行的指令的地址

* 2. SPSR_und保存有被中断模式的CPSR

* 3. CPSR中的M4-M0被设置为11011, 进入到und模式

* 4. 跳到0x4的地方执行程序 

*/

/* sp_und未设置, 先设置它 */

ldr sp, =0x34000000

/* 在und异常处理函数中有可能会修改r0-r12, 所以先保存 */

/* lr是异常处理完后的返回地址, 也要保存 */

  /* 保存现场 */

stmdb sp!, {r0-r12, lr}  

/* 处理und异常 */

mrs r0, cpsr

ldr r1, =und_string

bl printException

/* 恢复现场 */

ldmia sp!, {r0-r12, pc}^  /* ^会把spsr的值恢复到cpsr里 */

und_string:

.string "undefined instruction exception"

reset:

/* 关闭看门狗 */

ldr r0, =0x53000000

ldr r1, =0

str r1, [r0]

/* 设置MPLL, FCLK : HCLK : PCLK = 400m : 100m : 50m */

/* LOCKTIME(0x4C000000) = 0xFFFFFFFF */

ldr r0, =0x4C000000

ldr r1, =0xFFFFFFFF

str r1, [r0]

/* CLKDIVN(0x4C000014) = 0X5, tFCLK:tHCLK:tPCLK = 1:4:8  */

ldr r0, =0x4C000014

ldr r1, =0x5

str r1, [r0]

/* 设置CPU工作于异步模式 */

mrc p15,0,r0,c1,c0,0

orr r0,r0,#0xc0000000   //R1_nF:OR:R1_iA

mcr p15,0,r0,c1,c0,0

/* 设置MPLLCON(0x4C000004) = (92<<12)|(1<<4)|(1<<0) 

*  m = MDIV+8 = 92+8=100

*  p = PDIV+2 = 1+2 = 3

*  s = SDIV = 1

*  FCLK = 2*m*Fin/(p*2^s) = 2*100*12/(3*2^1)=400M

*/

ldr r0, =0x4C000004

ldr r1, =(92<<12)|(1<<4)|(1<<0)

str r1, [r0]

/* 一旦设置PLL, 就会锁定lock time直到PLL输出稳定

* 然后CPU工作于新的频率FCLK

*/

/* 设置内存: sp 栈 */

/* 分辨是nor/nand启动

* 写0到0地址, 再读出来

* 如果得到0, 表示0地址上的内容被修改了, 它对应ram, 这就是nand启动

* 否则就是nor启动

*/

mov r1, #0

ldr r0, [r1] /* 读出原来的值备份 */

str r1, [r1] /* 0->[0] */ 

ldr r2, [r1] /* r2=[0] */

cmp r1, r2   /* r1==r2? 如果相等表示是NAND启动 */

ldr sp, =0x40000000+4096 /* 先假设是nor启动 */

moveq sp, #4096  /* nand启动 */

streq r0, [r1]   /* 恢复原来的值 */

bl sdram_init

//bl sdram_init2 /* 用到有初始值的数组, 不是位置无关码 */

/* 重定位text, rodata, data段整个程序 */

bl copy2sdram

/* 清除BSS段 */

bl clean_bss

bl uart0_init

bl print1

/* 故意加入一条未定义指令 */

und_code:

.word 0xdeadc0de  /* 未定义指令 */

bl print2

//bl main  /* 使用BL命令相对跳转, 程序仍然在NOR/sram执行 */

ldr pc, =main  /* 绝对跳转, 跳到SDRAM */

halt:

b halt

6、按键中断

相比与异常，外部中断需要进行中断初始化才能正常触发中断，主要包括：

开总中断开关（CPSR中I位）

初始化中断控制器

初始化按键，设置为中断源（中断引脚，中断触发方式）

/* 初始化中断控制器 */

void interrupt_init(void)

{

INTMSK &= ~((1<<0) | (1<<2) | (1<<5));

}

/* 初始化按键, 设为中断源 */

void key_eint_init(void)

{

/* 配置GPIO为中断引脚 */

GPFCON &= ~((3<<0) | (3<<4));

GPFCON |= ((2<<0) | (2<<4));   /* S2,S3被配置为中断引脚 */

GPGCON &= ~((3<<6) | (3<<11));

GPGCON |= ((2<<6) | (2<<11));   /* S4,S5被配置为中断引脚 */

/* 设置中断触发方式: 双边沿触发 */

EXTINT0 |= (7<<0) | (7<<8);     /* S2,S3 */

EXTINT1 |= (7<<12);             /* S4 */

EXTINT2 |= (7<<12);             /* S5 */

/* 设置EINTMASK使能eint11,19 */

EINTMASK &= ~((1<<11) | (1<<19));

}

/* 复位之后, cpu处于svc模式

* 现在, 切换到usr模式

*/

mrs r0, cpsr         /* 读出cpsr */

bic r0, r0, #0xf     /* 修改M4-M0为0b10000, 进入usr模式 */

bic r0, r0, #(1<<7)  /* 清除I位, 使能中断 */

msr cpsr, r0

针对不同的硬件，其中断源可能各有不同：

中断向量表：

.text

.global _start

_start:

b reset          /* vector 0 : reset */

ldr pc, und_addr /* vector 4 : und */

ldr pc, swi_addr /* vector 8 : swi */

b halt /* vector 0x0c : prefetch aboot */

b halt /* vector 0x10 : data abort */

b halt /* vector 0x14 : reserved */

ldr pc, irq_addr /* vector 0x18 : irq */

b halt /* vector 0x1c : fiq */

und_addr:

.word do_und

swi_addr:

.word do_swi

irq_addr:

.word do_irq

中断处理：

do_irq:

/* 执行到这里之前:

* 1. lr_irq保存有被中断模式中的下一条即将执行的指令的地址

* 2. SPSR_irq保存有被中断模式的CPSR

* 3. CPSR中的M4-M0被设置为10010, 进入到irq模式

* 4. 跳到0x18的地方执行程序 

*/

/* sp_irq未设置, 先设置它 */

ldr sp, =0x33d00000

/* 保存现场 */

/* 在irq异常处理函数中有可能会修改r0-r12, 所以先保存 */

/* lr-4是异常处理完后的返回地址, 也要保存 */

sub lr, lr, #4

stmdb sp!, {r0-r12, lr}  

/* 处理irq异常 */

bl handle_irq_c

/* 恢复现场 */

ldmia sp!, {r0-r12, pc}^  /* ^会把spsr_irq的值恢复到cpsr里 */

中断服务子程序：

void handle_irq_c(void)

{

/* 分辨中断源 */

int bit = INTOFFSET;

/* 调用对应的处理函数 */

if (bit == 0 || bit == 2 || bit == 5)  /* eint0,2,eint8_23 */

{

key_eint_irq(bit); /* 处理中断, 清中断源EINTPEND */

}

/* 清中断 : 从源头开始清 */

SRCPND = (1< INTPND = (1<

}

按键中断源判别与处理：

void key_eint_irq(int irq)

{

unsigned int val = EINTPEND;

unsigned int val1 = GPFDAT;

unsigned int val2 = GPGDAT;

if (irq == 0) /* eint0 : s2 控制 D12 */

{

if (val1 & (1<<0)) /* s2 --> gpf6 */

{

/* 松开 */

GPFDAT |= (1<<6);

}

else

{

/* 按下 */

GPFDAT &= ~(1<<6);

}

}

else if (irq == 2) /* eint2 : s3 控制 D11 */

{

if (val1 & (1<<2)) /* s3 --> gpf5 */

{

/* 松开 */

GPFDAT |= (1<<5);

}

else

{

/* 按下 */

GPFDAT &= ~(1<<5);

}

}

else if (irq == 5) /* eint8_23, eint11--s4 控制 D10, eint19---s5 控制所有LED */

{

if (val & (1<<11)) /* eint11 */

{

if (val2 & (1<<3)) /* s4 --> gpf4 */

{

/* 松开 */

GPFDAT |= (1<<4);

}

else

{

/* 按下 */

GPFDAT &= ~(1<<4);

}

}

else if (val & (1<<19)) /* eint19 */

{

if (val2 & (1<<11))

{

/* 松开 */

/* 熄灭所有LED */

GPFDAT |= ((1<<4) | (1<<5) | (1<<6));

}

else

{

/* 按下: 点亮所有LED */

GPFDAT &= ~((1<<4) | (1<<5) | (1<<6));

}

}

}

EINTPEND = val;

}