ARM芯片学习（S5PV210开发）——代码重定位

什么是代码重定位

代码重定位就是代码的复制或者说搬移，把在A地址存放的代码复制一份到B地址，至于A、B地址，程序员是事先知道的，可以通过芯片的数据手册查询得知。并且由于某些条件的限制，有时候不能直接将代码下载到B地址，只能先下载到A地址，然后运行代码，将代码复制到B地址接着运行。

为什么要代码重定位

重定位不是为了优化性能，而是由于硬件的限制，不得不进行重定位。试想一下，我们拿到一台设备，只要上电就可以运行代码，那代码必定要先保存在设备的存储介质中，并且是掉电不丢失的存储介质，具有掉电不丢失性质的存储介质有磁盘、flash等，但是这些都不能用作内存，内存都是RAM。这就矛盾了，内存是掉电丢失，必然不能用于存储代码，但是代码又必须在内存里运行。所以就只能先把代码下载到磁盘、flash等掉电不丢失的存储介质中，在启动后通过重定位将代码重定位到内存中。

代码重定位的相关概念

芯片的启动过程、位置有关码和位置无关码、链接地址和下载地址、链接脚本、程序段的概念、ldr和adr加载标号地址时的区别。

1.对SOC启动过程不熟悉的可以参考博客《S5PV210的启动过程详解》。

2.位置有关码和位置无关码可以参考博客《位置有关码和位置无关码》。

3.链接地址和下载地址可以参考博客《嵌入式开发中的链接地址、运行地址、加载地址、存储地址、实际运行地址的区别》。

4.ldr和adr加载标号地址时的区别可以参考博客《ARM伪指令常用知识点讲解》。

重定位步骤：

1.重定位的思路

在编译链接程序时，通过链接脚本指定链接地址，当下载地址和链接地址不相等时就要代码重定位。重定位思路就是通过先执行一段位置无关码，将代码复制一份到链接地址处，接着执行后续代码。

2.链接脚本

SECTIONS

{

. = 0xd0024000;

.text : {

start.o

* (.text)

}

.data : {

* (.data)

}

bss_start = .; 

.bss : {

* (.bss)

}

bss_end  = .;

}

汇编代码

/*

 * 文件名： led.s

 * 作者： 朱老师

 * 描述： 演示重定位（在SRAM内部重定位）

 */

#define WTCON 0xE2700000

#define SVC_STACK 0xd0037d80

.global _start // 把_start链接属性改为外部，这样其他文件就可以看见_start了

_start:

// 第1步：关看门狗（向WTCON的bit5写入0即可）

ldr r0, =WTCON

ldr r1, =0x0

str r1, [r0]

// 第2步：设置SVC栈

ldr sp, =SVC_STACK

// 第3步：开/关icache

mrc p15,0,r0,c1,c0,0; // 读出cp15的c1到r0中

//bic r0, r0, #(1<<12) // bit12 置0  关icache

orr r0, r0, #(1<<12) // bit12 置1  开icache

mcr p15,0,r0,c1,c0,0;

// 第4步：重定位

// adr指令用于加载_start当前运行地址

adr r0, _start  // adr加载时就叫短加载

// ldr指令用于加载_start的链接地址:0xd0024000

ldr r1, =_start // ldr加载时如果目标寄存器是pc就叫长跳转，如果目标寄存器是r1等就叫长加载

// bss段的起始地址

ldr r2, =bss_start // 就是我们重定位代码的结束地址，重定位只需重定位代码段和数据段即可

cmp r0, r1 // 比较_start的运行时地址和链接地址是否相等

beq clean_bss // 如果相等说明不需要重定位，所以跳过copy_loop，直接到clean_bss

// 如果不相等说明需要重定位，那么直接执行下面的copy_loop进行重定位

// 重定位完成后继续执行clean_bss。

// 用汇编来实现的一个while循环

copy_loop:

ldr r3, [r0], #4    // 源

str r3, [r1], #4 // 目的   这两句代码就完成了4个字节内容的拷贝

cmp r1, r2 // r1和r2都是用ldr加载的，都是链接地址，所以r1不断+4总能等于r2

bne copy_loop

// 清bss段，其实就是在链接地址处把bss段全部清零

clean_bss:

ldr r0, =bss_start

ldr r1, =bss_end

cmp r0, r1 // 如果r0等于r1，说明bss段为空，直接下去

beq run_on_dram // 清除bss完之后的地址

mov r2, #0

clear_loop:

str r2, [r0], #4 // 先将r2中的值放入r0所指向的内存地址（r0中的值作为内存地址），

cmp r0, r1 // 然后r0 = r0 + 4

bne clear_loop

run_on_dram:

// 长跳转到led_blink开始第二阶段

ldr pc, =led_blink // ldr指令实现长跳转

// 从这里之后就可以开始调用C程序了

//bl led_blink // bl指令实现短跳转

// 汇编最后的这个死循环不能丢

b .