datasheet
单片机
单片机>ARM单片机> arm linux 启动过程

arm linux 启动过程

发布者：灵感驿站最新更新时间：2016-06-16 来源: eefocus关键字：arm  linux  启动过程 手机看文章 扫描二维码
随时随地手机看文章
分享到
微博
QQ
微信
LinkedIn
arm-linux启动过程

 

1. kernel运行的史前时期和内存布局

 

在arm平台下，zImage.bin压缩镜像是由bootloader加载到物理内存，然后跳到zImage.bin里一段程序，它专门于将被压缩的kernel解压缩到KERNEL_RAM_PADDR开始的一段内存中，接着跳进真正的kernel去执行。该kernel的执行起点是stext函数，定义于arch/arm/kernel/head.S。

 

在分析stext函数前，先介绍此时内存的布局如下图所示

 

arm linux 启动过程

 

在开发板tqs3c2440中，SDRAM连接到内存控制器的Bank6中，它的开始内存地址是0x30000000，大小为64M，即0x20000000。 ARM Linux kernel将SDRAM的开始地址定义为PHYS_OFFSET。经bootloader加载kernel并由自解压部分代码运行后，最终kernel被放置到KERNEL_RAM_PADDR（=PHYS_OFFSET + TEXT_OFFSET，即0x30008000）地址上的一段内存，经此放置后，kernel代码以后均不会被移动。

 

在进入kernel代码前，即bootloader和自解压缩阶段，ARM未开启MMU功能。因此kernel启动代码一个重要功能是设置好相应的页表，并开启MMU功能。为了支持MMU功能，kernel镜像中的所有符号，包括代码段和数据段的符号，在链接时都生成了它在开启MMU时，所在物理内存地址映射到的虚拟内存地址。

 

以arm kernel第一个符号（函数）stext为例，在编译链接，它生成的虚拟地址是0xc0008000，而放置它的物理地址为0x30008000（还记得这是PHYS_OFFSET+TEXT_OFFSET吗？）。实际上这个变换可以利用简单的公式进行表示：va = pa – PHYS_OFFSET + PAGE_OFFSET。Arm linux最终的kernel空间的页表，就是按照这个关系来建立。

 

之所以较早提及arm linux 的内存映射，原因是在进入kernel代码，里面所有符号地址值为清一色的0xCXXXXXXX地址，而此时ARM未开启MMU功能，故在执行stext函数第一条执行时，它的PC值就是stext所在的内存地址（即物理地址，0x30008000）。因此，下面有些代码，需要使用地址无关技术。

 

2．一览stext函数

 

stext函数定义在Arch/arm/kernel/head.S，它的功能是获取处理器类型和机器类型信息，并创建临时的页表，然后开启MMU功能，并跳进第一个C语言函数start_kernel。

 

stext函数的在前置条件是：MMU, D-cache, 关闭; r0 = 0, r1 = machine nr, r2 = atags prointer.

 

代码如下：

 

[cpp] view plaincopyprint?
  1.   .section ".text.head", "ax"  
  2.   
  3. (stext)  
  4.   
  5.  /* 设置CPU运行模式为SVC，并关中断 */  
  6.   
  7.   msr  cpsr_c, #PSR_F_BIT | PSR_I_BIT | SVC_MODE @ ensure svc mode  
  8.   
  9.                                      @ and irqs disabled  
  10.   
  11.   mrc p15, 0, r9, c0, c0        @ get processor id  
  12.   
  13.   bl    __lookup_processor_type         @ r5=procinfo r9=cupid  
  14.   
  15. /* r10指向cpu对应的proc_info记录 */  
  16.   
  17.    movs  r10, r5                         @ invalid processor (r5=0)?  
  18.   
  19.   beq __error_p                    @ yes, error 'p'  
  20.   
  21.   bl    __lookup_machine_type            @ r5=machinfo  
  22.   
  23. /* r8 指向开发板对应的arch_info记录 */  
  24.   
  25.    movs  r8, r5                           @ invalid machine (r5=0)?  
  26.   
  27.   beq __error_a                    @ yes, error 'a'  
  28.   
  29. /* __vet_atags函数涉及bootloader造知kernel物理内存的情况，我们暂时不分析它。 */  
  30.   
  31.   bl    __vet_atags  
  32.   
  33. /*  创建临时页表 */  
  34.   
  35.   bl    __create_page_tables  
  36.   
  37.   
  38.   
  39.   /*
  40.  
  41.    * The following calls CPU specific code in a position independent 
  42.  
  43.    * manner.  See arch/arm/mm/proc-*.S for details.  r10 = base of 
  44.  
  45.    * xxx_proc_info structure selected by __lookup_machine_type 
  46.  
  47.    * above.  On return, the CPU will be ready for the MMU to be 
  48.  
  49.    * turned on, and r0 will hold the CPU control register value. 
  50.  
  51.    */  
  52.   
  53.  /* 这里的逻辑关系相当复杂，先是从proc_info结构中的中跳进__arm920_setup函数，
  54.  
  55.   * 然后执__enable_mmu 函数。最后在__enable_mmu函数通过mov pc, r13来执行__switch_data， 
  56.  
  57.   * __switch_data函数在最后一条语句，鱼跃龙门，跳进第一个C语言函数start_kernel。 
  58.    */  
  59.   
  60.   ldr   r13, __switch_data             @ address to jump to after  
  61.   
  62.                                      @ mmu has been enabled  
  63.   
  64.   adr  lr, __enable_mmu        @ return (PIC) address  
  65.   
  66.   add pc, r10, #PROCINFO_INITFUNC  
  67.   
  68. OC(stext)  


 

3 __lookup_processor_type 函数

 __lookup_processor_type 函数是一个非常讲究技巧的函数，如果你将它领会，也将领会kernel了一些魔法。

Kernel代码将所有CPU信息的定义都放到.proc.info.init段中，因此可以认为.proc.info.init段就是一个数组，每个元素都定义了一个或一种CPU的信息。目前__lookup_processor_type使用该元素的前两个字段cpuid和mask来匹配当前CPUID，如果满足CPUID & mask == cpuid，则找到当前cpu的定义并返回。 

下面是tqs3c2440开发板，CPU的定义信息，cpuid = 0x41009200，mask = 0xff00fff0。如果是码是运行在tqs3c2440开发板上，那么函数返回下面的定义：

 

[cpp] view plaincopyprint?
  1.        .section ".proc.info.init", #alloc, #execinstr  
  2.   
  3.    
  4.   
  5.        .type       __arm920_proc_info,#object  
  6.   
  7. __arm920_proc_info:  
  8.   
  9.        .long       0x41009200  
  10.   
  11.        .long       0xff00fff0  
  12.   
  13.        .long   PMD_TYPE_SECT | \  
  14.   
  15.               PMD_SECT_BUFFERABLE | \  
  16.   
  17.               PMD_SECT_CACHEABLE | \  
  18.   
  19.               PMD_BIT4 | \  
  20.   
  21.               PMD_SECT_AP_WRITE | \  
  22.   
  23.               PMD_SECT_AP_READ  
  24.   
  25.        .long   PMD_TYPE_SECT | \  
  26.   
  27.               PMD_BIT4 | \  
  28.   
  29.               PMD_SECT_AP_WRITE | \  
  30.   
  31.               PMD_SECT_AP_READ  
  32.   
  33.       /* __arm920_setup函数在stext的未尾被调用，请往回看。*/  
  34.   
  35.        b     __arm920_setup  
  36.   
  37.        .long       cpu_arch_name  
  38.   
  39.        .long       cpu_elf_name  
  40.   
  41.        .long       HWCAP_SWP | HWCAP_HALF | HWCAP_THUMB  
  42.   
  43.        .long       cpu_arm920_name  
  44.   
  45.        .long       arm920_processor_functions  
  46.   
  47.        .long       v4wbi_tlb_fns  
  48.   
  49.        .long       v4wb_user_fns  
  50.   
  51. #ifndef CONFIG_CPU_DCACHE_WRITETHROUGH   
  52.   
  53.        .long       arm920_cache_fns  
  54.   
  55. #else   
  56.   
  57.        .long       v4wt_cache_fns  
  58.   
  59. #endif   
  60.   
  61.        .size __arm920_proc_info, . - __arm920_proc_info  


 

[cpp] view plaincopyprint?
  1. /* 
  2.  * Read processor ID register (CP#15, CR0), and look up in the linker-built 
  3.  * supported processor list.  Note that we can't use the absolute addresses 
  4.  * for the __proc_info lists since we aren't running with the MMU on 
  5.  * (and therefore, we are not in the correct address space).  We have to 
  6.  * calculate the offset. 
  7.  * 
  8.  *   r9 = cpuid 
  9.  * Returns: 
  10.  *   r3, r4, r6 corrupted 
  11.  *   r5 = proc_info pointer in physical address space 
  12.  *   r9 = cpuid (preserved) 
  13.  */   
  14. __lookup_processor_type:  
  15.       /* adr 是相对寻址，它的寻计算结果是将当前PC值加上3f符号与PC的偏移量，
  16.        * 而PC是物理地址，因此r3的结果也是3f符号的物理地址 */  
  17.   
  18.        adr  r3, 3f  
  19.   
  20.       /* r5值为__proc_info_bein, r6值为__proc_ino_end，而r7值为.，
  21.        * 也即3f符号的链接地址。请注意，在链接期间，__proc_info_begin和 
  22.        * __proc_info_end以及.均是链接地址，也即虚执地址。 
  23.        */  
  24.   
  25.        ldmda     r3, {r5 - r7}  
  26.   
  27.      /* r3为3f的物理地址，而r7为3f的虚拟地址。结果是r3为虚拟地址与物理地址的差值，即PHYS_OFFSET - PAGE_OFFSET。*/  
  28.   
  29.        sub  r3, r3, r7                     @ get offset between virt&phys  
  30.   
  31.      /* r5为__proc_info_begin的物理地址, 即r5指针__proc_info数组的首地址 */  
  32.   
  33.        add r5, r5, r3                     @ convert virt addresses to  
  34.   
  35.      /* r6为__proc_info_end的物理地址 */  
  36.   
  37.        add r6, r6, r3                     @ physical address space  
  38.   
  39.      /* 读取r5指向的__proc_info数组元素的CPUID和mask值 */  
  40.   
  41. 1:    ldmia      r5, {r3, r4}                  @ value, mask  
  42.   
  43.      /* 将当前CPUID和mask相与，并与数组元素中的CPUID比较是否相同
  44.       * 若相同，则找到当前CPU的__proc_info定义，r5指向访元素并返回。 
  45.       */  
  46.   
  47.        and  r4, r4, r9                     @ mask wanted bits  
  48.   
  49.        teq  r3, r4  
  50.   
  51.        beq 2f  
  52.   
  53.      /* r5指向下一个__proc_info元素 */  
  54.   
  55.        add r5, r5, #PROC_INFO_SZ        @ sizeof(proc_info_list)  
  56.   
  57.      /* 是否遍历完所有__proc_info元素 */  
  58.   
  59.        cmp r5, r6  
  60.   
  61.        blo  1b  
  62.   
  63.      /* 找不到则返回NULL */  
  64.   
  65.        mov r5, #0                          @ unknown processor  
  66.   
  67. 2:    mov pc, lr  
  68.   
  69. ENDPROC(__lookup_processor_type)  
  70.   
  71.        .long       __proc_info_begin  
  72.        .long       __proc_info_end  
  73. 3:    .long       .  
  74.        .long       __arch_info_begin  
  75.        .long       __arch_info_end  
 

4 __lookup_machine_type 函数

__lookup_machine_type 和__lookup_processor_type像对孪生兄弟，它们的行为都是很类似的：__lookup_machine_type根据r1寄存器的机器编号到.arch.info.init段的数组中依次查找机器编号与r1相同的记录。它使了与它孪生兄弟同样的手法进行虚拟地址到物理地址的转换计算。

 

在介绍函数，我们先分析tqs3c2440开发板的机器信息的定义：

[cpp] view plaincopyprint?
  1. Arch/arm/include/asm/mach/arch.h   
  2.   
  3. #define MACHINE_START(_type,_name)                  \   
  4.   
  5. static const struct machine_desc __mach_desc_##_type      \  
  6.   
  7.  __used                                           \  
  8.   
  9.  __attribute__((__section__(".arch.info.init"))) = { \  
  10.   
  11.        .nr          = MACH_TYPE_##_type,              \  
  12.   
  13.        .name            = _name,  
  14.   
  15.    
  16.   
  17. #define MACHINE_END                       \   
  18.   
  19. };  


 

MACHINE_START宏用于定义一个.arch.info.init段的数组元素。.nr元素就是函数要比较的变量。Tqs3c2440开发板相应的定义如下：

 

[cpp] view plaincopyprint?
  1. MACHINE_START(S3C2440, "TQ2440")  
  2.   
  3.        .phys_io = S3C2410_PA_UART,  
  4.   
  5.        .io_pg_offst   = (((u32)S3C24XX_VA_UART) >> 18) & 0xfffc,  
  6.   
  7.        .boot_params       = S3C2410_SDRAM_PA + 0x100,  
  8.   
  9.    
  10.   
  11.        .init_irq   = s3c24xx_init_irq,  
  12.   
  13.        .map_io         = tq2440_map_io,  
  14.   
  15.        .init_machine  = tq2440_machine_init,  
  16.   
  17.        .timer             = &s3c24xx_timer,  
  18.   
  19. MACHINE_END  


 

这是一个struct machine_desc结构，在后面的C代码（start_kernel开始执行的代码）会使用该变量对象。在tqs3c2440开发中的__lookup_machine_type函数就是返回该对象指针。

这里涉及很多函数指针，它们都是在start_kernel函数里在各种阶段进行初始化的回函数。如map_io指向的tq2440_map_io就是在建立好内核页表后，再调用它来针对开发板的各种IO端口来建立相关的映射和页表。

至于__loopup_machine_type的代码就不作详细分析，请对比__lookup_processor_type来自行分析。代码如下：

 

[cpp] view plaincopyprint?
  1. /* 
  2.  
  3.  * Lookup machine architecture in the linker-build list of architectures. 
  4.  
  5.  * Note that we can't use the absolute addresses for the __arch_info 
  6.  
  7.  * lists since we aren't running with the MMU on (and therefore, we are 
  8.  
  9.  * not in the correct address space).  We have to calculate the offset. 
  10.  
  11.  * 
  12.  
  13.  *  r1 = machine architecture number 
  14.  
  15.  * Returns: 
  16.  
  17.  *  r3, r4, r6 corrupted 
  18.  
  19.  *  r5 = mach_info pointer in physical address space 
  20.  
  21.  */  
  22.   
  23. __lookup_machine_type:  
  24.   
  25.        adr  r3, 3b  
  26.   
  27.        ldmia      r3, {r4, r5, r6}  
  28.   
  29.        sub  r3, r3, r4                     @ get offset between virt&phys  
  30.   
  31.        add r5, r5, r3                     @ convert virt addresses to  
  32.   
  33.        add r6, r6, r3                     @ physical address space  
  34.   
  35. 1:    ldr   r3, [r5, #MACHINFO_TYPE] @ get machine type  
  36.   
  37.        teq  r3, r1                           @ matches loader number?  
  38.   
  39.        beq 2f                         @ found  
  40.   
  41.        add r5, r5, #SIZEOF_MACHINE_DESC     @ next machine_desc  
  42.   
  43.        cmp r5, r6  
  44.   
  45.        blo  1b  
  46.   
  47.        mov r5, #0                          @ unknown machine  
  48.   
  49. 2:    mov pc, lr  
  50.   
  51. ENDPROC(__lookup_machine_type)  

 

 

5. 为kernel建立临时页表

前面提及到，kernel里面的所有符号在链接时，都使用了虚拟地址值。在完成基本的初始化后，kernel代码将跳到第一个C语言函数start_kernl来执行，在哪个时候，这些虚拟地址必须能够对它所存放在真正内存位置，否则运行将为出错。为此，CPU必须开启MMU，但在开启MMU前，必须为虚拟地址到物理地址的映射建立相应的面表。在开启MMU后，kernel指并不马上将PC值指向start_kernl，而是要做一些C语言运行期的设置，如堆栈，重定义等工作后才跳到start_kernel去执行。在此过程中，PC值还是物理地址，因此还需要为这段内存空间建立va = pa的内存映射关系。当然，本函数建立的所有页表都会在将来paging_init销毁再重建，这是临时过度性的映射关系和页表。

 

在介绍__create_table_pages前，先认识一个macro pgtbl，它将KERNL_RAM_PADDR – 0x4000的值赋给rd寄存器，从下面的使用中可以看它，该值是页表在物理内存的基础，也即页表放在kernel开始地址下的16K的地方。

[cpp] view plaincopyprint?
  1.    
  2.   
  3. .macro    pgtbl, rd  
  4.   
  5.        ldr   \rd, =(KERNEL_RAM_PADDR - 0x4000)  
  6.   
  7. .endm  


 

[cpp] view plaincopyprint?
  1. /* 
  2.  * Setup the initial page tables.  We only setup the barest 
  3.  * amount which are required to get the kernel running, which 
  4.  * generally means mapping in the kernel code. 
  5.  * 
  6.  * r8  = machinfo 
  7.  * r9  = cpuid 
  8.  * r10 = procinfo 
  9.  * 
  10.  * Returns: 
  11.  *  r0, r3, r6, r7 corrupted 
  12.  *  r4 = physical page table address 
  13.  */  
  14. __create_page_tables:  
  15.   /* r4 = KERNEL_RAM_PADDR – 0x4000 = 0x30004000
  16.    * 后面的C代码中的swapper_pg_dir变量，它的值也指向0x30004000 
  17.    * 内存地址，不过它的值是虚拟内存地址，即0xc0004000 
  18.    */  
  19.        pgtbl       r4                         @ page table address  
  20.   
  21.    /* 将从r4到KERNEL_RAP_PADDR的16K页表空间清空。 */  
  22.   
  23.        mov r0, r4  
  24.        mov r3, #0  
  25.        add r6, r0, #0x4000  
  26.   
  27. 1:     str   r3, [r0], #4  
  28.        str   r3, [r0], #4  
  29.        str   r3, [r0], #4  
  30.        str   r3, [r0], #4  
  31.        teq  r0, r6  
  32.        bne  1b  
  33.   
  34.    
  35.      /* 还记得r10指向开发板相应的proc_info元素吗？这里它将的mm_mmuflags值读到r7中。
  36.       * PROCINFO_MM_MMUFLAGS值为8，可对应上面列出来的__arm920_proc_info结构或你相应开发板结构的值来查看该mmu_flags值。 
  37.       * 这里的flags就是用于设置目录项的flags。查看该mmu_flags的定义，发现它是要求一级页表是section。 
  38.       */  
  39.   
  40.        ldr   r7, [r10, #PROCINFO_MM_MMUFLAGS] @ mm_mmuflags  
  41.   
  42.        /*
  43.         * Create identity mapping for first MB of kernel to 
  44.         * cater for the MMU enable.  This identity mapping 
  45.         * will be removed by paging_init().  We use our current program 
  46.         * counter to determine corresponding section base address. 
  47.         */  
  48.   
  49.        /* r3 = ((pc >> 20) << 20) | r7， 即取PC以1M向下对齐的地址。R6 = pc >> 20也即r6 = 0x300(pgd_idx)，
  50.         * 即PC对所有1M内存空间，在页表中的下标。                                     
  51.         * R7值表明该目录项是section，即它映射的大小是1M。故刚好一个目录项就可以映射kernel上的1M空间。 
  52.         * 这个暂时的va = pa映射只建立1M大小内存的，而不需要建立整个kernel镜像范围的映射。 
  53.         * 因为这个va = pa的映射只有当前汇编语言才使用，一量跳进start_kernl后，这将不会用到了。而汇编代码在链接时， 
  54.         * 已将它安排到代码段的最前面了。 
  55.   
  56.         mov r6, pc, lsr #20                     @ start of kernel section 
  57.         orr   r3, r7, r6, lsl #20         @ flags + kernel base 
  58.  
  59.        /* 将目录内空写到页表相应位置，即((uint32_t *)r4)[pgd_idx] = r3 */  
  60.    
  61.        str   r3, [r4, r6, lsl #2]         @ identity mapping  
  62.   
  63.    
  64.        /* 上面代码段为[pc &(~0xfffff), (pc + 0xfffff) &(~0xfffff)]的物理内存空间建立了va = pa的映射关系。*/  
  65.   
  66.        /* 下面为kernel镜像所占有空间，即KERNL_START到KERNEL_END建立内存映射，
  67.         * 映射关系为：va = pa – PHYS + PAGR_OFFSET。注意，这里的KENEL_START是kernel空间开始的虚拟地址。 
  68.         * 这里的目录表项同样是section，即一个项映射1M的内存。 
  69.         */  
  70.   
  71.   
  72.        /* KERNEL_START = PAGE_OFFSET + TEXT_OFFSET，
  73.         * r0 = ((uint32_t *)(r4))[ (KERNEL_START & 0xff000000) >> 20]， 
  74.         * 即r0指向KERNEL_START& 0xff000000(即kernel以16M向下对齐的)虚拟地址，所在项表目录中的位置。 
  75.  
  76.        add r0, r4,  #(KERNEL_START & 0xff000000) >> 18 
  77.  
  78.       /* r0 = ((uint32_t *)r0)[(KERNEL_START & 0x00f00000) >> 20] 
  79.        * 执行前r0指向kernel以16M向下对齐的虚执地址，而这里再加上KERNEL_START未以16M向对齐部分的偏移量。 
  80.        * 将原来r3的值写到页表目录中。R3的值就是之前已建立好va=pa映射的那个PA值。 
  81.        */  
  82.   
  83.        str   r3, [r0, #(KERNEL_START & 0x00f00000) >> 18]!  
  84.   
  85.       /* r6为kernel镜像的尾部虚拟地址。*/  
  86.   
  87.        ldr   r6, =(KERNEL_END - 1)  
  88.   
  89.       /* 指向下一个即将要填写的目录项 */  
  90.   
  91.        add r0, r0, #4  
  92.   
  93.       /* r6指向KERNEL_END- 1虚拟地址所在的目录表项的位置 */  
  94.   
  95.       add r6, r4, r6, lsr #18  
  96. 1:    cmp       r0, r6  
  97.   
  98.       /* 每填一个目录项，后一个比前一个所指向的物理地址大1M。*/  
  99.       add r3, r3, #1 << 20  
  100.       strls r3, [r0], #4  
  101.       bls   1b  
  102.   
  103.  #ifdef CONFIG_XIP_KERNEL   
  104.        /* 忽略，不分析这种情况 */  
  105. #endif   
  106.   
  107.     /* 通常kernel的启动参数由bootloader放到了物理内存的第1个M上，所以需要为RAM上的第1个M建立映射。
  108.      * 上面已为PHYS_OFFSET + TEXT_OFFSET建立了映射，如果TEXT_OFFSET小于0x00100000的话， 
  109.      * 上面代码应该也为SDRAM的第一个M建立了映射，但如果大于0x0010000则不会。 
  110.      * 所以这里无论如何均为SDRAM的第一个M建立映射（不知分析对否，还请指正）。 
  111.      */  
  112.        add r0, r4, #PAGE_OFFSET >> 18  
  113.        orr   r6, r7, #(PHYS_OFFSET & 0xff000000)  
  114.        .if    (PHYS_OFFSET & 0x00f00000)  
  115.        orr   r6, r6, #(PHYS_OFFSET & 0x00f00000)  
  116.        .endif  
  117.        str   r6, [r0]  
  118.   
  119. #ifdef CONFIG_DEBUG_LL   
  120.        /*略去 */  
  121. #if defined(CONFIG_ARCH_NETWINDER) || defined(CONFIG_ARCH_CATS)   
  122.        /* 略去 */  
  123. #endif   
  124.   
  125. #ifdef CONFIG_ARCH_RPC   
  126.  /* 略去 */  
  127. #endif   
  128.   
  129. #endif   
  130.   
  131.        mov pc, lr  
  132. ENDPROC(__create_page_tables)  
 

一口气将__create_pages_table分析完，但里涉及的代码还是需要细细品读。尤其是右移20位和18位两个地方与页表目录项的地址关系比较复杂。执行完该函数后，虚拟内存和物理内存的映射关系如下图所示：

 

arm linux 启动过程

 

6. 开启MMU

 

看完页表的建立，想必开启MMU的代码也是小菜一碟吧。此函数的主要功能是将页表的基址加到cp15中的面表指针寄存器，同时设置域访问(domain access)寄存器。

 

[cpp] view plaincopyprint?
  1. /* 
  2.  * Setup common bits before finally enabling the MMU.  Essentially 
  3.  * this is just loading the page table pointer and domain access 
  4.  * registers. 
  5.  */  
  6. __enable_mmu:  
  7.  /* 这里设置是否为非对齐内存访问产生异常 */  
  8. #ifdef CONFIG_ALIGNMENT_TRAP   
  9.        orr   r0, r0, #CR_A  
  10. #else   
  11.        bic   r0, r0, #CR_A  
  12. #endif   
  13.  /* 是否禁用数据缓存功能*/  
  14. #ifdef CONFIG_CPU_DCACHE_DISABLE   
  15.        bic   r0, r0, #CR_C  
  16. #endif   
  17.  /* 是否禁用CPU_BPREDICT ?，不是很清楚此选项 */  
  18. #ifdef CONFIG_CPU_BPREDICT_DISABLE   
  19.        bic   r0, r0, #CR_Z  
  20. #endif   
  21.  /* 是否禁用指令缓存功能 */  
  22. #ifdef CONFIG_CPU_ICACHE_DISABLE   
  23.        bic   r0, r0, #CR_I  
  24. #endif   
  25.   
  26.       /* 设置域访问寄存器的值。这里设置每个domain的属性是否上面建立的页表中，
  27.        * 每个目录项的damon值一起进行访问控制检查。具体情况请参考ARM处理器手册。 
  28.        */  
  29.   
  30.        mov r5, #(domain_val(DOMAIN_USER, DOMAIN_MANAGER) | \  
  31.                     domain_val(DOMAIN_KERNEL, DOMAIN_MANAGER) | \  
  32.                     domain_val(DOMAIN_TABLE, DOMAIN_MANAGER) | \  
  33.                     domain_val(DOMAIN_IO, DOMAIN_CLIENT))  
  34.        mcr p15, 0, r5, c3, c0, 0           @ load domain access register  
  35.        mcr p15, 0, r4, c2, c0, 0           @ load page table pointer  
  36.        b     __turn_mmu_on  
  37. ENDPROC(__enable_mmu)  
  38.   
  39. /*
  40.  * Enable the MMU.  This completely changes the structure of the visible 
  41.  * memory space.  You will not be able to trace execution through this. 
  42.  * If you have an enquiry about this, *please* check the linux-arm-kernel 
  43.  * mailing list archives BEFORE sending another post to the list. 
  44.  * 
  45.  *  r0  = cp#15 control register 
  46.  *  r13 = *virtual* address to jump to upon completion 
  47.  * 
  48.  * other registers depend on the function called upon completion 
  49.  */  
  50.   
  51.        .align      5  
  52. __turn_mmu_on:  
  53.        mov r0, r0  
  54.   
  55.       /* 将r0的值写到控制寄存器中。这里，终于开启MMU功能了。
  56.        * 查阅手册说控制寄存器的0位置1表示开启MMU，但这里r0的第0是多少呢（还请大家指正） 
  57.        */  
  58.   
  59.        mcr p15, 0, r0, c1, c0, 0           @ write control reg  
  60.        mrc p15, 0, r3, c0, c0, 0           @ read id reg  
  61.   
  62.      /* 这里的两个mov似乎是否流水线有关的，开启MMU语句后面几条是不能进行内存寻址的。但仍未搞明白具体东西的。*/  
  63.        mov r3, r3  
  64.        mov r3, r3  
  65.   
  66.      /* 转跳到r13的函数中去，r13为__mmap_switched函数的虚拟地址，
  67.       * 从stext函数的未尾可以找到它的赋值。故从此开始pc的值就真正在内存的虚拟地址空间了。 
  68.       */  
  69.   
  70.        mov pc, r13  
  71. ENDPROC(__turn_mmu_on)  

 

7．__mmap_switched函数

__mmap_switched函数专用来设置C语言的执行环境，比如重定位工作，堆栈，以及BSS段的清零。 

__switch_data变量先定义了一系里面处量的数据，如重定位和数据段的地址，BSS段的地址，pocessor_id和__mach_arch_type变量的地址等。

 

[cpp] view plaincopyprint?
  1.        .type       __switch_data, %object  
  2. __switch_data:  
  3.        .long       __mmap_switched  
  4.        .long       __data_loc                  @ r4  
  5.        .long       _data                           @ r5  
  6.        .long       __bss_start                  @ r6  
  7.        .long       _end                            @ r7  
  8.        .long       processor_id               @ r4  
  9.        .long       __machine_arch_type         @ r5  
  10.        .long       __atags_pointer                  @ r6  
  11.        .long       cr_alignment                @ r7  
  12.        .long       init_thread_union + THREAD_START_SP @ sp  
  13.    
  14. /*
  15.  * The following fragment of code is executed with the MMU on in MMU mode, 
  16.  * and uses absolute addresses; this is not position independent. 
  17.  * 
  18.  *  r0  = cp#15 control register 
  19.  *  r1  = machine ID 
  20.  *  r2  = atags pointer 
  21.  *  r9  = processor ID 
  22.  */  
  23. __mmap_switched:  
  24.        adr  r3, __switch_data + 4  
  25.        /* r4 = __data_loc, r5 = _data, r6 = _bss_start, r7 = _end */  
  26.        ldmia      r3!, {r4, r5, r6, r7}  
  27.   
  28.       /* 下面这段代码类似于这段C代码, 即将整个数据段从__data_loc拷贝到_data段。
  29.        * if (__data_loc  == _data || _data != _bass_start) 
  30.        *    memcpy(_data, __data_loc, _bss_start - _data); 
  31.        */  
  32.   
  33.        cmp      r4, r5                           @ Copy data segment if needed  
  34. 1:     cmpne    r5, r6  
  35.        ldrne       fp, [r4], #4  
  36.        strne       fp, [r5], #4  
  37.        bne  1b  
  38.   
  39.        /* 将BSS段，也即从_bss_start到_end的内存清零。 */  
  40.   
  41.        mov fp, #0                          @ Clear BSS (and zero fp)  
  42. 1:     cmp     r6, r7  
  43.        strcc       fp, [r6],#4  
  44.        bcc  1b  
  45.   
  46.    /* r4 = processor_id,
  47.     * r5 = __machine_arch_type 
  48.     * r6 = __atags_pointer 
  49.     * r7 = cr_alignment 
  50.     * sp = init_thread_union + THREAD_START_SP 
  51.     * 为什么将栈顶指针设置为init_thread_union + THREAD_START_SP 
  52.     * init_head_union 变量是一个大小为THREAD_SIZE的union，它在编译时，放到数据段的前面。 
  53.     * 初步估计这块空间是内核堆栈。故在跳入C语言代码时，它SP的值设置为init_thread_union + THREAD_START_SP。 
  54.     * 注意THREAD_START_SP定义为THREAD_SIZE – 8，中间为什么留出8个字节呢？是与ARM的堆栈操作有关吗？ 还有用专向start_kernel函数传递参数？ 
  55.     */  
  56.    
  57.        ldmia      r3, {r4, r5, r6, r7, sp}  
  58.        str   r9, [r4]                 @ Save processor ID  
  59.        str   r1, [r5]                 @ Save machine type  
  60.        str   r2, [r6]                 @ Save atags pointer  
  61.        bic   r4, r0, #CR_A                    @ Clear 'A' bit  
  62.   
  63.     /* cr_alignment变量的后面接着放置cr_no_alignment, 
  64.      * r0为打开alignment检测时，控制寄存器的值，而r4为关闭时的值, 
  65.      * 这里分将将打开和关闭alignment检查的控制寄存器的值写到 
  66.      * cr_alignment和cr_no_alignement变量中。 
  67.      */  
  68.   
  69.        stmia      r7, {r0, r4}                  @ Save control register values  
  70.   
  71.      /* 跳到start_kernel函数，此函数代码用纯C来实现，它会调用各个平台的相关初始化函数，
  72.       * 来实现不同平台的初始化工作。至此，arm linux的启动工作完成。 
  73.       */  
  74.   
  75.        b     start_kernel  
  76. ENDPROC(__mmap_switched)  

 

全文完, by linyt

关键字：arm  linux  启动过程 引用地址：arm linux 启动过程

上一篇：ARM Linux启动过程学习
下一篇：arm 嵌入式LINUX启动过程(1)

推荐阅读最新更新时间：2024-03-16 14:57

ARM白皮书聚焦下一代处理器架构
   日前，ARM联合高通发布了技术白皮书，称基于 ARMv8-A 的高集成 SoC(系统级芯片)将引发新一代变革，目前 SoC主要基于ARMv7-A架构。(更多独家财经新闻，请加微信号cbn-yicai) 　　手机芯片中包括了计算、通信等不同处理器模块，但计算模块主要根据ARM处理器搭建，ARM处理器因此有“芯片中的芯片”之称。白皮书披露，超过 95% 的Android 设备芯片基于 ARM架构，从 25 美元的入门级智能手机到 600 美元的顶级智能手机。 　　在ARM披露的业务模式中，高通等“ARM 许可人”将ARM处理器与其他处理器、技术模块集成后，向市场推出各自不同品牌的SoC。 　　目前，联发科新的4G旗舰处理器M
[手机便携]
贸泽电子开售STMicroelectronics配备FPU的 STM32H5 Arm Cortex-M33 32位MCU
202 3 年 10 月 31 日 – 提供超丰富半导体和电子元器件™的业界知名新品引入 (NPI) 代理商贸泽电子 (Mouser Electronics) 即日起供货STMicroelectronicsg的STM32H5 MCU。STM32H5是首个可访问片上系统 (SoC) 安全服务的MCU系列，适用于工业自动化、医疗、智慧城市、智能家居、个人电子产品和通信领域的新一代智能互联设备。 贸泽电子供应的 STMicroelectronics STM32H5 是搭载Arm ® Cortex ® -M33 32位RISC内核的高性能微控制器 (MCU)，包含浮点运算单元 (FPU)，工作频率高达250 MHz，兼具高性能、安
[嵌入式]
多方位对比ARM和x86 CPU两大架构现在发展如何？
　　随便逮住一个人问他知不知道CPU，我想他的答案一定会是肯定的，但是如果你再问他知道ARM和X86架构么？这两者的区别又是什么？绝大多数的人肯定是一脸懵逼。今天小编就带你深入了解CPU的这两大架构：ARM和X86。以后出去装X就靠它了！ 　　 　　重温下CPU是什么鬼 　　中央处理单元（CPU）主要由运算器、控制器、寄存器三部分组成，从字面意思看运算器就是起着运算的作用，控制器就是负责发出CPU每条指令所需要的信息，寄存器就是保存运算或者指令的一些临时文件，这样可以保证更高的速度。 　　CPU有着处理指令、执行操作、控制时间、处理数据四大作用，打个比喻来说，CPU就像我们的大脑，帮我们完成各种各样的生理活动。因此如果没有
[单片机]
多方位对比<font color='red'>ARM</font>和x86 CPU两大架构现在发展如何？
ARM基础知识教程三
简介：ARM基础知识-ARM中异常中断的种类 **复位（RESET)** 当处理器复位引脚有效时，系统产生复位异常中断，程序跳转到复位异常中断处理程序处执行。复位异常中断通常用在下面几种情况下：系统加电时；系统复位时；跳转到复位中断向量处执行成为软复位。 **未定义的指令** 当ARM处理器或者是系统中的协处理器认为当前指令未定义时，产生未定义的指令异常中断，可以通过改异常中断机制仿真浮点向量运算。 **软件中断** 这是一个由用户定义的中断指令。可用于用户模式下的程序调用特权操作指令。在实时操作系统中可以通过该机制西线系统功能调用。 **指令与取终止（PrefechAbort)** 如果处理器预取的指令的地址不存
[单片机]
负债也要疯狂收购ARM：孙正义的又一次豪赌
     　　新浪科技 郑峻发自美国硅谷 　　对于孙正义来说，疯狂从来都是一个褒义词。这位自称孙子后人的日本企业家，在商场上的运筹帷幄令人惊叹。在过去的25年时间里，孙正义用一笔笔令人惊叹的交易，从白手起家打造了一个全球性科技帝国。310亿美元收购英国移动芯片巨头ARM，是他疯狂投资史上的又一个大手笔，但毫无疑问也不是最后一笔。 　　每两三年爆发一次 　　“我总是有一些大的想法，每两到三年就会爆发一次”，孙正义如是说。虽然已经年近六十，但他身上那种冒险的基因却从未改变。 　　的确，每隔几年，孙正义总会以一笔天价收购震惊业界。上个月孙正义先后抛售部分阿里股份和出售游戏开发商SuperCell，总计套现近186亿美元，
[手机便携]
新手福利：ARM常用概念须知
文章罗列了关于ARM的22个常用概念。包括一些使用注意事项，ARM启动代码设计，ARM处理器运行模式，ARM体系结构所支持的异常类型和一些基本操作方法等等。 1.ARM中一些常见英文缩写解释 MSB：最高有效位; LSB：最低有效位; AHB：先进的高性能总线; VPB：连接片内外设功能的VLSI外设总线; EMC：外部存储器控制器; MAM：存储器加速模块; VIC：向量中断控制器; SPI：全双工串行接口; CAN：控制器局域网，一种串行通讯协议; PWM：脉宽调制器; ETM：嵌入式跟踪宏; CPSR：当前程序状态寄存器; SPSR：程序保护状态寄存器; 2.MAM 使用注意事项： 答：当改变 MAM 定时值时，必须
[单片机]
STM32的启动过程
由于微控制器上电之后没有办法定位Main函数的位置，因为变量和函数的地址都是由编译器在编译的时候自行分配的，所以Main函数的在微控制器内部的位置是可变的，所以每个微控制器都有一个复位后到跳转的到Main函数的过程，这个过程都是由启动文件来完成的，不管是51、AVR都有，有些时候是由开发环境自己提供了这样的一个启动文件。我们只需管从Main函数开始的应用程序即可，简化了我们的工作。 在STM32微控制器中ST公司已经帮我们完成了这样一个启动文件的工作，不管是MTK环境还是IAR环境都已经集成好了。新一代的Cort ex 的微控制器在启动方式上较ARM7/9都有较大的变化，ARM7/9中复位后从固定的地址（0x0）取出第一条指令
[单片机]
IAR推出新版IAR Embedded Workbench for Arm功能安全版，该版本配备经过认证的静态代码分析功能
IAR推出新版IAR Embedded Workbench for Arm功能安全版，该版本配备经过认证的静态代码分析功能 瑞典乌普萨拉，2024年2月20日 – 全球领先的嵌入式系统开发软件解决方案供应商IAR宣布 ：推出其旗舰产品IAR Embedded Workbench for Arm功能安全版的最新版本9.50.3。此次发布进一步加强了IAR支持开发人员创建安全、可靠和符合标准的嵌入式应用程序的承诺，涵盖了汽车、医疗设备、工业自动化和消费电子等多个行业。该版本中最重要的新功能是经过认证的C-STAT，这是专为安全关键应用程序设计的静态代码分析工具。 IAR Embedded Workbench for Ar
[嵌入式]
IAR推出新版IAR Embedded Workbench for <font color='red'>Arm</font>功能安全版，该版本配备经过认证的静态代码分析功能
热门资源推荐
热门放大器推荐
更多
小广播
添点儿料...
无论热点新闻、行业分析、技术干货……
热门活动
换一批
更多
有奖直播报名中！抢占工业4.1先机，WT·世健科技日等你来！
设计资源 培训 开发板 精华推荐

最新单片机文章
何立民专栏 单片机及嵌入式宝典

北京航空航天大学教授，20余年来致力于单片机与嵌入式系统推广工作。

更多精选电路图
换一换 更多 相关热搜器件
更多热门文章
更多每日新闻
更多往期活动
11月22日历史上的今天
厂商技术中心
随便看看

About Us 关于我们 客户服务 联系方式 器件索引 网站地图 最新更新 手机版

站点相关： 综合资讯 51单片机 PIC单片机 AVR单片机 ARM单片机 嵌入式系统 汽车电子 消费电子 数据处理 视频教程 电子百科 其他技术 STM32 MSP430 单片机资源下载 单片机习题与教程

词云： 1 2 3 4 5 6 7 8 9 10

北京市海淀区中关村大街18号B座15层1530室 电话:(010)82350740 邮编：100190

电子工程世界版权所有 京B2-20211791 京ICP备10001474号-1 电信业务审批[2006]字第258号函 京公网安备 11010802033920号 Copyright © 2005-2024 EEWORLD.com.cn, Inc. All rights reserved