AT93C46汇编读写示例程序; 说明: 软件包仅适用于93C46 8位存储器结构状态,软件包可嵌入到80C51 ROM中任一空间。
; fosc = 12MHz
;----------------------------------------------------------
R31 EQU 1FH
CS EQU P1.0 ;片选端
SK EQU P1.1 ;模拟时钟信号输出端
DI EQU P1.2 ;串行数据输出端
DO EQU P1.3 ;串行数据输入端
;----------------------------------------------------------
ORG 0000H
JMP MAIN
ORG 0100H
MAIN:
MOV R0,#7FH
CLR A
MOV @R0,A
DJNZ R0,$-2
MOV SP,#60H
MAIN1:
MOV R0,#30H
MOV R7,#16
MOV A,#1
MOV @R0,A
INC R0
INC A
DJNZ R7,$-3
CALL EWNE ;擦写允许
MOV A,#01100000B ;地址"11xxxxx"
CALL INADR ;输出地址
CALL EWNE ;片擦除(将整个存储器置为"1")
MOV A,#01000000B ;片擦除地址
CALL INADREW ;输出地址
CALL DLY10ms
CALL RD16 ;读指定地址单元的数据
CALL WRITE ;将数据写入指定地址单元
CALL ERASE ;擦除(将指定地址单元置为"1")
MOV A,#01H ;地址
CALL INADREW ;输出地址
CALL DLY10ms
CALL RD16 ;读
CALL EWNE ;擦/写禁止
MOV A,#0 ;地址"00xxxxx"
CALL INADR ;输出地址
JMP MAIN1
;==========================================================
;----------------------------------------------------------
;将存在80C51内RAM 30H为首地址的16字节数据依次写入93C46首址00H的EEPROM
;注意: 93C46上电复位后,芯片处于写保护状态,所以在擦写操作前,应开启"写允许".
;否则无法写入数据.
WRITE:
MOV A,#01100000B ;地址"11xxxxx"
CALL INADR ;输出地址
MOV R0,#30H ;置源数据区首址
MOV R1,#00H ;置93C46写入单元首址
MOV R7,#16 ;字节数
CALL WRIT6
RET
;----------------------------------------------------------
;将AT93C46 首址为00H的16字节数据读出并存入80C51以30H为首址的内RAM中
RD16: MOV R0,#20H ;置数据存储区首址
MOV A,#00H ;置93C46读出单元首地址
MOV R7,#16 ;字节数送R7
LCALL STATRD ;启动读
LCALL INADR ;输出93C46读出单元首址
RD160:
LCALL READ ;读出一个字节数据
MOV @R0,A ;存一个字节数据
INC R0 ;指向下一存储单元地址
DJNZ R7,RD160 ;判16字节数据读完否?未完继续
CLR CS ;16字节数据读完,置93C46低功耗备用状态
CALL DLY10ms ;延时10ms,以便进行芯片的其它功能操作
RET
;----------------------------------------------------------
;入口: 数据区首址在R0,93C46单元地址在R1,写入的字节数在R7中
WRIT6:
LCALL STATWR ;启动写
MOV A,R1 ;置93C46写入单元地址
LCALL INADR ;输出93C46写入地址单元
MOV A,@R0 ;读写入数据
LCALL WRIT ;写入一个字节
LCALL DLY1ms ;延时1ms
INC R0 ;指向8051下一个数据地址
INC R1 ;指向93C46下一个写入单元地址
DJNZ R7,WR61 ;判6字节数据写完否?未完继续
CLR CS ;93C46进入备用状态,降低功耗
CALL DLY10ms
RET
WR61: JB DO,WRIT6 ;判REDAY/BUSY,DO=1,写入下一字节
SJMP WR61 ;DO=0,转等待
;==========================================================
; 启动读子程序
; 说明: STATRD子程序输出启动和读操作代码"110"
;----------------------------------------------------------
STATRD:
CLR CS ;片选置低
CLR SK ;时钟置低
SETB CS
SETB DI ;置启动"1"
SETB SK ;时钟上升沿输出启动信号"1"
CLR SK
SETB SK ;时钟上升沿输出"1"
CLR SK
CLR DI ;置输出"0"
SETB SK ;时钟上升沿输出"0"
CLR SK ;时钟置低
RET
;----------------------------------------------------------
; 启动写子程序
; 说明: STATWR子程序输出启动和写操作代码"101"
;----------------------------------------------------------
STATWR:
CLR CS ;片选置低
CLR SK ;时钟置低
SETB CS ;置片选
SETB DI ;置启动"1"
SETB SK ;时钟上升沿输出启动信号"1"
CLR SK
CLR DI ;置输出"0"
SETB SK ;时钟上升沿输出"0"
CLR SK
SETB DI ;置输出"1"
SETB SK ;时钟上升沿输出"1"
CLR SK ;时钟置低
RET
;----------------------------------------------------------
; 擦写允许/禁止启动和操作代码 "100"
; 该子程序可用于: 擦写允许(EWEN)、写禁止(EWDS)、片写(WRAL)、片擦除(ERAL),
; 只是各自的地址不同而也.
; 擦写允许/禁止操作代码"100",地址"11xxxxx"/"00xxxxx"
;----------------------------------------------------------
EWNE:
CLR CS ;片选置低
CLR SK ;时钟置低
SETB CS ;置片选
SETB DI ;置启动"1"
SETB SK ;时钟上升沿输出启动信号"1"
CLR SK
CLR DI ;置输出"0"
SETB SK ;时钟上升沿输出"0"
CLR SK
CLR DI ;置输出"0"
SETB SK ;时钟上升沿输出"1"
CLR SK ;时钟置低
RET
;----------------------------------------------------------
; 擦指令ERASE 启动和操作代码 "111"
;----------------------------------------------------------
ERASE:
CLR CS ;片选置低
CLR SK ;时钟置低
SETB CS ;置片选
SETB DI ;置启动"1"
SETB SK ;时钟上升沿输出启动信号"1"
CLR SK
SETB DI ;置输出"1"
SETB SK ;时钟上升沿输出"0"
CLR SK
SETB DI ;置输出"1"
SETB SK ;时钟上升沿输出"1"
CLR SK ;时钟置低
RET
;----------------------------------------------------------
; 输出读写单元地址子程序
; 入口: 7位地址已存在A中D6~D0
;----------------------------------------------------------
INADR:
MOV R2,#7 ;置写入地址位数(存储单元8位结构时,地址为7位)
RLC A ;先左移一位,地址移至D7~D1,D0无效
IR1: CLR SK ;时钟置低
RLC A ;左移一位
MOV DI,C ;存入DI端口
SETB SK ;时钟上升沿输出至93C46DI端
DJNZ R2,IR1 ;判断7位地址写完否,未完继续
RET
;----------------------------------------------------------
; 输出擦单元地址子程序
INADREW:
CALL INADR
CLR CS
NOP
SETB CS
JNB DO,$ ; DO=0,表示编程正在进行;
; DO=1,表示该指定地址的寄存器单元已擦完,可以执行下一条指令。
RET
;----------------------------------------------------------
; 读一个字节子程序
; 出口: 8位数据存在A中
;----------------------------------------------------------
READ: CLR SK ;时钟置低
MOV R2,#8 ;置读入位数8
RD1: SETB SK ;时钟上升沿读入一位数据
NOP
MOV C,DO ;存入Cy
RLC A ;左移入A中
CLR SK ;时钟置低
DJNZ R2,RD1 ;判8位数据读完否?未完继续
RET
;----------------------------------------------------------
;确良写一个字节子程序
; 入口: 写入数据须事先存入A中.
; 若需写入多个字节数据,须在1ms后,93C46 DO 端出现高电平后才能重新启动写入.
;----------------------------------------------------------
WRIT:
MOV R2,#8 ;置写入位数8
WR1: CLR SK ;时钟置低
RLC A ;A中数据移一位至Cy中
MOV DI,C ;数据传送至DI端
nop
SETB SK ;时钟上升沿输出至93C46
DJNZ R2,WR1 ;判8位数据写完否?未完继续
CLR CS ;8位数据写完,CS下降沿启动93C46擦写
SETB CS ;CS次高位,以使DO端REDAY/BUSY状态位号有效
RET
;----------------------------------------------------------
DLY1ms: ;延时1ms子程序
MOV R31,#29 ;
L2: PUSH R31
L3: DJNZ R31,L3
POP R31
DJNZ R31,L2
RET
DLY10ms: ;延时10ms子程序
MOV R31,#100
L20: PUSH R31
L30: DJNZ R31,L30
POP R31
DJNZ R31,L20
RET
;==========================================================
END
独辟蹊径品内核： Linux 内核源代码导读
控制系统计算机辅助设计 — MATLAB语言与应用
设计资源 培训 开发板 精华推荐
- 【下载】LAT1439 关于STM32H745的MC SDK电机控制工程问题的解决办法
- 【下载】LAT1444 ADC采样中的阻抗匹配计算方法
- 【下载】LAT1446 TrustZone应用中串口通信的DMA传输失败问题
- 【下载】LAT1450 不断电情况下修改RDP选项并生效的解决方案
- 【下载】LAT1455 分辨OEMiROT的Bash与BAT脚本
- 【下载】LAT1457 Keil工程使用NEAI库的异常问题
- MCU今年的重点：NPU和64位对于MCU来说，跑AI也是非常重点的应用之一。前两天，就连实时控制派系的MCU TI C2000都开始搭载NPU和64位化。可见，MCU正在加速向AI进化。...
- STM32转AT32代码转换1 引言在嵌入式开发中，我们经常会遇到更换单片机芯片的事情，若芯片是同一厂家的还好说，若是不同厂家的则需要重新写，重新调，重新去学 ...
- LXTAL低频晶振起振异常可能有哪些原因？在GD32MCU系统中，LXTAL低频晶振一般选择32768Hz无源晶体，该晶体内部一般为50K欧姆左右，比较大，相较于高频晶振不太容易起振，所以经常会 ...
- 关于GD32F150R8的多卡门控系统设计的分析和应用1方案介绍这个门控系统方案是使用常见的 MIFARE 卡，使用上只判断卡片上的 ID 而不写入任何资料，板上记录了 8 组卡片 ID，当已注册 ...
- SWD端口无法连接如何排查大家在调试GD32MCU的时候是否也碰到过SWD调试端口无法连接的情况？SWD端口无法连接的原因有很多，有时候排查没有思路，可能会耽误大家的时 ...
- 调试器连接MCU不稳定怎么办？
- 非直接烧录ST对GD的代码移植
- MCU上电不启动的可能原因分析
- 更改晶振后如何修改配置？
- 遇见春天，“愚”你同乐 快来与keysight一起学习 光通信测试测量解决方案 下载赢好礼！
- 阅1SP0350V SCALE-2单通道即插即用型门极驱动器，参与PI答题享好礼！
- #Micropython大作战#第三弹：抢楼！大家一起来整理micropython资料
- 免费申请评测：和小伙伴们一起畅玩STM32F769I
- 挑战“仙童”历史知识 精美礼品等你拿！
- 共抗疫情，少出门多学习。领取下载积分，让学习资料到你碗里！
- TI 中国大学计划20周年官网“幸运雨”了，你还不来抢？
- 有奖报名 | 安富利邀您参与2022国际工业博览会！（11月30日-12月4日，上海）
- 了解TI光影艺术，观看DLP系列视频，抢楼赢礼！
京公网安备 11010802033920号